[arch-commits] Commit in (4 files)

[Frederik Schwan]

    Date: Wednesday, December 15, 2021 @ 13:59:48
  Author: freswa
Revision: 1073076

move ripgrep-all to community

Added:
  ripgrep-all/
  ripgrep-all/repos/
  ripgrep-all/trunk/
  ripgrep-all/trunk/PKGBUILD

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Added: ripgrep-all/trunk/PKGBUILD
===================================================================
--- ripgrep-all/trunk/PKGBUILD	                        (rev 0)
+++ ripgrep-all/trunk/PKGBUILD	2021-12-15 13:59:48 UTC (rev 1073076)
@@ -0,0 +1,47 @@
+# Maintainer: Frederik Schwan <freswa at archlinux dot org>
+# Contributor: Chris Lane <aur at chrislane dot com>
+# Contributor: phiresky <phireskyde+aur at gmail.com>
+# Contributor: Julien Nicoulaud <julien DOT nicoulaud AT gmail DOT com>
+
+pkgname=ripgrep-all
+pkgver=0.9.6
+pkgrel=3
+pkgdesc="rga: ripgrep, but also search in PDFs, E-Books, Office documents, zip, tar.gz, etc."
+arch=('x86_64')
+url='https://github.com/phiresky/ripgrep-all'
+license=('AGPL3')
+depends=('ripgrep')
+makedepends=('cargo')
+optdepends=(
+  'ffmpeg: for the ffmpeg adapter'
+  'graphicsmagick: for the pdfpages adapter'
+  'pandoc: for the pandoc adapter'
+  'poppler: for the poppler adapter'
+  'tesseract: for the tesseract adapter'
+)
+source=("https://github.com/phiresky/ripgrep-all/archive/refs/tags/v${pkgver}.tar.gz")
+b2sums=('184ad8835c00913eba07c6f922683b372f790ba9a04141bb98fa7510095cc392b750361ddd0cbe0e2ebf832b24249c0203f07b1e494ae7810ca1585868895bf2')
+
+prepare() {
+  cd ripgrep-all-${pkgver}
+  cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
+}
+
+build() {
+  cd ripgrep-all-${pkgver}
+  export RUSTUP_TOOLCHAIN=stable
+  export CARGO_TARGET_DIR=target
+  cargo build --frozen --release --all-features
+}
+
+check() {
+  cd ripgrep-all-${pkgver}
+  export RUSTUP_TOOLCHAIN=stable
+  cargo test --frozen --all-features
+}
+
+package() {
+  cd ripgrep-all-${pkgver}
+  install -Dm 755 target/release/rga "${pkgdir}"/usr/bin/rga
+  install -Dm 755 target/release/rga-preproc "${pkgdir}"/usr/bin/rga-preproc
+}