[arch-commits] Commit in lib32-nspr/repos (2 files)

[Jan Steffens]

    Date: Saturday, December 18, 2021 @ 14:13:40
  Author: heftig
Revision: 1076955

archrelease: copy trunk to multilib-testing-x86_64

Added:
  lib32-nspr/repos/multilib-testing-x86_64/
  lib32-nspr/repos/multilib-testing-x86_64/PKGBUILD
    (from rev 1076954, lib32-nspr/trunk/PKGBUILD)

----------+
 PKGBUILD |   52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

Copied: lib32-nspr/repos/multilib-testing-x86_64/PKGBUILD (from rev 1076954, lib32-nspr/trunk/PKGBUILD)
===================================================================
--- multilib-testing-x86_64/PKGBUILD	                        (rev 0)
+++ multilib-testing-x86_64/PKGBUILD	2021-12-18 14:13:40 UTC (rev 1076955)
@@ -0,0 +1,52 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Daniel Wallace <danielwallace at gtmanfred dot com>
+# Contributor: kfgz <kfgz at interia pl>
+# Contributor: Ionut Biru <ibiru at archlinux dot org>
+
+pkgname=lib32-nspr
+pkgver=4.33
+pkgrel=1
+pkgdesc="Netscape Portable Runtime (32-bit)"
+url="https://developer.mozilla.org/en-US/docs/Mozilla/Projects/NSPR"
+arch=(x86_64)
+license=(MPL GPL)
+depends=(lib32-glibc nspr)
+makedepends=(zip mercurial)
+_revision=5f753966dc01e1872eb4fee6e7b6d0a4fd3daad2
+source=("hg+https://hg.mozilla.org/projects/nspr#revision=$_revision")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd nspr
+  hg id -t | sed 's/^NSPR_//;s/_RTM$//;s/_/./g'
+}
+
+prepare() {
+  cd nspr
+}
+
+build() {
+  cd nspr
+  ./configure \
+      --prefix=/usr \
+      --libdir=/usr/lib32 \
+      --includedir=/usr/include/nspr \
+      --enable-optimize \
+      --disable-debug \
+      --disable-64bit
+  make ${SOURCE_DATE_EPOCH:+
+    SH_NOW="${SOURCE_DATE_EPOCH}000000"
+    SH_DATE="$(date --utc --date="@$SOURCE_DATE_EPOCH" '+%Y-%m-%d %T')"
+  }
+}
+
+package() {
+  cd nspr
+  make DESTDIR="$pkgdir" install
+  ln -s nspr.pc "$pkgdir/usr/lib32/pkgconfig/mozilla-nspr.pc"
+
+  rm -r "$pkgdir"/usr/{bin,share,include}
+}
+
+# vim:set sw=2 et: