[arch-commits] Commit in haskell-servant-server/repos (2 files)

[Felix Yan]

    Date: Sunday, December 19, 2021 @ 02:18:34
  Author: felixonmars
Revision: 1078146

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-servant-server/repos/community-staging-x86_64/
  haskell-servant-server/repos/community-staging-x86_64/PKGBUILD
    (from rev 1078145, haskell-servant-server/trunk/PKGBUILD)

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Copied: haskell-servant-server/repos/community-staging-x86_64/PKGBUILD (from rev 1078145, haskell-servant-server/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-12-19 02:18:34 UTC (rev 1078146)
@@ -0,0 +1,50 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=servant-server
+pkgname=haskell-servant-server
+pkgver=0.18.3
+pkgrel=58
+pkgdesc="A family of combinators for defining webservices APIs and serving them"
+url="https://haskell-servant.readthedocs.org/"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-base-compat' 'haskell-aeson' 'haskell-base64-bytestring'
+         'haskell-http-api-data' 'haskell-http-media' 'haskell-http-types'
+         'haskell-network-uri' 'haskell-monad-control' 'haskell-network' 'haskell-servant'
+         'haskell-sop-core' 'haskell-string-conversions' 'haskell-resourcet' 'haskell-tagged'
+         'haskell-transformers-base' 'haskell-wai' 'haskell-wai-app-static' 'haskell-warp'
+         'haskell-word8')
+makedepends=('ghc' 'haskell-hspec' 'haskell-hspec-wai' 'haskell-should-not-typecheck'
+             'haskell-quickcheck' 'haskell-safe' 'haskell-wai-extra' 'haskell-temporary'
+             'haskell-transformers-compat')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('c89a676de870cba67b86e818a87f144a316294d6ef786bdcc20017da48089cf0c25fc434ed0b42e81053fae4ad1ac0628443e4d0afb7f17fa53a1b5516272d28')
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test --show-details=direct
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}