[arch-commits] Commit in haskell-hpack/repos (2 files)

[Felix Yan]

    Date: Tuesday, December 21, 2021 @ 22:22:42
  Author: felixonmars
Revision: 1082656

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-hpack/repos/community-staging-x86_64/
  haskell-hpack/repos/community-staging-x86_64/PKGBUILD
    (from rev 1082655, haskell-hpack/trunk/PKGBUILD)

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Copied: haskell-hpack/repos/community-staging-x86_64/PKGBUILD (from rev 1082655, haskell-hpack/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-12-21 22:22:42 UTC (rev 1082656)
@@ -0,0 +1,47 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Daniel Nagy <danielnagy at gmx de>
+# Contributor: Daniel Micay <danielmicay at gmail.com>
+
+pkgname=haskell-hpack
+_hkgname=hpack
+pkgver=0.34.4
+pkgrel=96
+pkgdesc="A modern format for Haskell packages"
+url="https://github.com/sol/hpack#readme"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-bifunctors' 'haskell-cryptonite' 'haskell-glob'
+         'haskell-http-client' 'haskell-http-client-tls' 'haskell-http-types'
+         'haskell-infer-license' 'haskell-scientific' 'haskell-unordered-containers'
+         'haskell-vector' 'haskell-yaml')
+makedepends=('ghc' 'haskell-hunit' 'haskell-quickcheck' 'haskell-hspec' 'haskell-interpolate'
+             'haskell-mockery' 'haskell-temporary')
+source=("https://hackage.haskell.org/packages/archive/$_hkgname/$pkgver/$_hkgname-${pkgver}.tar.gz")
+sha512sums=('90dee8766955e44fd760ac9bead2f68de23763f56778dd7691d30a71cb37e5834093f3c9b382ffaa677bbbef0a3c0c9f7abeeb34343906e6d6b692481eacd7c9')
+
+build() {
+  cd $_hkgname-$pkgver
+  runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm
+  runhaskell Setup build $MAKEFLAGS
+  runhaskell Setup register --gen-script
+  runhaskell Setup unregister --gen-script
+  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+  cd $_hkgname-$pkgver
+  runhaskell Setup test || echo "https://github.com/sol/hpack/issues/358"
+}
+
+package() {
+  cd $_hkgname-$pkgver
+
+  install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+  install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+  runhaskell Setup copy --destdir="$pkgdir"
+  install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+  rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}