[arch-commits] Commit in python-fiona/repos (2 files)

[Antonio Rojas]

    Date: Thursday, December 23, 2021 @ 17:13:16
  Author: arojas
Revision: 1083311

archrelease: copy trunk to community-staging-x86_64

Added:
  python-fiona/repos/community-staging-x86_64/
  python-fiona/repos/community-staging-x86_64/PKGBUILD
    (from rev 1083310, python-fiona/trunk/PKGBUILD)

----------+
 PKGBUILD |   51 +++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)

Copied: python-fiona/repos/community-staging-x86_64/PKGBUILD (from rev 1083310, python-fiona/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-12-23 17:13:16 UTC (rev 1083311)
@@ -0,0 +1,51 @@
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+
+_pkg=Fiona
+pkgname=python-${_pkg,,}
+pkgver=1.8.20
+pkgrel=6
+pkgdesc="Read and write geographic data files"
+arch=(x86_64)
+url="https://github.com/Toblerity/Fiona"
+license=(BSD)
+depends=(
+    gdal
+    python-attrs
+    python-certifi
+    python-click
+    python-click-plugins
+    python-cligj
+    python-munch
+    python-six
+)
+optdepends=(
+    'python-shapely: fio-calc functionnality'
+    'python-boto3: s3 support'
+)
+makedepends=(cython python-setuptools)
+checkdepends=(python-pytest python-boto3 python-pytz python-shapely)
+#source=(https://files.pythonhosted.org/packages/source/${_pkg::1}/${_pkg}/${_pkg}-${pkgver}.tar.gz)
+# need sources generated with newer cython than the one used in pypi sources
+# https://github.com/Toblerity/Fiona/issues/1043
+source=(https://github.com/Toblerity/Fiona/archive/$pkgver/$pkgname-$pkgver.tar.gz)
+sha256sums=('9db20c25cd5657e12cf2b60bdd33954064ca31b7048b605885d34b390f898018')
+
+build() {
+  cd ${_pkg}-${pkgver}
+  python setup.py build
+}
+
+check() {
+  cd ${_pkg}-${pkgver}
+  mv fiona{,.bak} # Avoid non-working local import
+  local python_version=$(python -c 'import sys; print(".".join(map(str, sys.version_info[:2])))')
+  # Currently they are 67 failing tests but no time to investigate
+  PYTHONPATH="${PWD}"/build/lib.linux-${CARCH}-${python_version}/ pytest -m "not wheel" || echo "Warning: failed tests"
+  mv fiona{.bak,}
+}
+
+package() {
+  cd ${_pkg}-${pkgver}
+  python setup.py install --prefix=/usr --root="${pkgdir}" --skip-build --optimize=1
+  install -Dm644 LICENSE.txt -t "${pkgdir}"/usr/share/licenses/${pkgname}
+}