[arch-commits] Commit in darktable/repos (2 files)

[Caleb Maclennan]

    Date: Saturday, December 25, 2021 @ 10:25:12
  Author: alerque
Revision: 1083550

archrelease: copy trunk to community-testing-x86_64

Added:
  darktable/repos/community-testing-x86_64/
  darktable/repos/community-testing-x86_64/PKGBUILD
    (from rev 1083549, darktable/trunk/PKGBUILD)

----------+
 PKGBUILD |   52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

Copied: darktable/repos/community-testing-x86_64/PKGBUILD (from rev 1083549, darktable/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2021-12-25 10:25:12 UTC (rev 1083550)
@@ -0,0 +1,52 @@
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+# Maintainer: Morten Linderud <foxboron at archlinux.org>
+# Maintainer: Caleb Maclennan <caleb at alerque.com>
+# Contributor: Sergej Pupykin <pupykin.s+arch at gmail.com>
+# Contributor: Christian Himpel <chressie at gmail dot com>
+# Contributor: Johannes Hanika <hanatos at gmail dot com>
+
+pkgname=darktable
+epoch=2
+pkgver=3.8.0
+pkgrel=2
+pkgdesc="Utility to organize and develop raw images"
+arch=(x86_64)
+url="https://darktable.org"
+license=(GPL3)
+depends=(pugixml libjpeg-turbo colord-gtk libgphoto2 openexr lensfun iso-codes zlib
+         exiv2 flickcurl openjpeg2 graphicsmagick lua osm-gps-map libsecret openmp
+         gmic libavif)
+optdepends=('dcraw: base curve script'
+            'perl-image-exiftool: base curve script'
+            'imagemagick: base curve and noise profile scripts'
+            'ghostscript: noise profile script'
+            'gnuplot: noise profile script')
+makedepends=(cmake intltool desktop-file-utils llvm clang python-jsonschema libwebp)
+source=("https://github.com/darktable-org/darktable/releases/download/release-${pkgver}/darktable-${pkgver}.tar.xz"{,.asc})
+sha256sums=('2e65c7c78d074ad218e3ef7a8c3051a8ea78f4a0406386667859645e5e4bf705'
+            'SKIP')
+validpgpkeys=(C4CBC150699956E2A3268EF5BB5CC8295B1779C9  # darktable releases <release at darktable.org>
+              F10F9686652B0E949FCD94C318DCA123F949BD3B) # Pascal Obry <pascal at obry.net>
+
+build() {
+    cmake -B build -S ${pkgname}-${pkgver} \
+        -DCMAKE_INSTALL_PREFIX=/usr \
+        -DCMAKE_INSTALL_LIBDIR=/usr/lib \
+        -DCMAKE_INSTALL_LIBEXECDIR=/usr/lib \
+        -DCMAKE_BUILD_TYPE=Release \
+        -DBINARY_PACKAGE_BUILD=1 \
+        -DBUILD_USERMANUAL=False \
+        -DUSE_LIBSECRET=ON \
+        -DUSE_LUA=ON \
+        -DUSE_COLORD=ON \
+        -DBUILD_CURVE_TOOLS=ON \
+        -DBUILD_NOISE_TOOLS=ON \
+        -DRAWSPEED_ENABLE_LTO=ON \
+        -DPROJECT_VERSION=${pkgver}
+    make -C build
+}
+
+package() {
+    make -C build DESTDIR="${pkgdir}" install
+    ln -s darktable/libdarktable.so "${pkgdir}"/usr/lib/libdarktable.so
+}