[arch-commits] Commit in rz-cutter/repos (2 files)

[Antonio Rojas]

    Date: Saturday, December 25, 2021 @ 11:59:51
  Author: arojas
Revision: 1083589

archrelease: copy trunk to community-staging-x86_64

Added:
  rz-cutter/repos/community-staging-x86_64/
  rz-cutter/repos/community-staging-x86_64/PKGBUILD
    (from rev 1083588, rz-cutter/trunk/PKGBUILD)

----------+
 PKGBUILD |   58 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)

Copied: rz-cutter/repos/community-staging-x86_64/PKGBUILD (from rev 1083588, rz-cutter/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-12-25 11:59:51 UTC (rev 1083589)
@@ -0,0 +1,58 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Maintainer: Santiago Torres-Arias <santiago[at]archlinux[dot]org>
+# Contributor: Aaron McDaniel (mcd1992) <'aur' at the domain 'fgthou.se'>
+
+pkgname=rz-cutter
+_gitcommit=78a9a112099e0d045773d77f4b1166fc3b7d2eef
+pkgver=2.0.4
+pkgrel=1
+pkgdesc='Qt and C++ GUI for rizin reverse engineering framework'
+url='https://github.com/rizinorg/cutter'
+arch=('x86_64')
+license=('GPL3')
+depends=('rizin' 'capstone' 'qt5-base' 'qt5-svg' 'qt5-webengine' 'icu' 'python' 'jupyter'
+         'pyside2' 'python-shiboken2' 'graphviz' 'gcc-libs' 'syntax-highlighting')
+makedepends=('git' 'cmake' 'ninja' 'shiboken2' 'qt5-tools')
+optdepends=('rz-ghidra: ghidra decompiler plugin')
+source=("git+https://github.com/rizinorg/cutter#commit=${_gitcommit}"
+        "git+https://github.com/rizinorg/cutter-translations")
+sha512sums=('SKIP'
+            'SKIP')
+b2sums=('SKIP'
+        'SKIP')
+
+pkgver() {
+  cd cutter
+  git describe --tags --match 'v*' | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+prepare() {
+  cd cutter
+  git config 'submodule.src/translations.url' "${srcdir}/cutter-translations"
+  git submodule update --init src/translations
+}
+
+build() {
+  cd cutter
+  cmake -B build \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_BUILD_TYPE=None \
+    -DCUTTER_ENABLE_PYTHON=ON \
+    -DCUTTER_ENABLE_PYTHON_BINDINGS=ON \
+    -DCUTTER_USE_BUNDLED_RIZIN=OFF \
+    -DCUTTER_USE_ADDITIONAL_RIZIN_PATHS=OFF \
+    -DCUTTER_ENABLE_CRASH_REPORTS=OFF \
+    -DCUTTER_ENABLE_GRAPHVIZ=ON \
+    -Wno-dev \
+    -G Ninja
+  ninja -C build
+}
+
+package() {
+  cd cutter
+  DESTDIR="${pkgdir}" ninja -C build install
+  install -d "${pkgdir}/usr/share/doc/${pkgname}"
+  cp -a docs/* "${pkgdir}/usr/share/doc/${pkgname}"
+}
+
+# vim: ts=2 sw=2 et: