[arch-commits] Commit in gmic/repos (2 files)

[Antonio Rojas]

    Date: Saturday, December 25, 2021 @ 17:43:14
  Author: arojas
Revision: 1083713

archrelease: copy trunk to community-staging-x86_64

Added:
  gmic/repos/community-staging-x86_64/
  gmic/repos/community-staging-x86_64/PKGBUILD
    (from rev 1083712, gmic/trunk/PKGBUILD)

----------+
 PKGBUILD |   61 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 61 insertions(+)

Copied: gmic/repos/community-staging-x86_64/PKGBUILD (from rev 1083712, gmic/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-12-25 17:43:14 UTC (rev 1083713)
@@ -0,0 +1,61 @@
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Sergej Pupykin <pupykin.s+arch at gmail.com>
+# Contributor: Jan "heftig" Steffens <jan.steffens at gmail.com>
+# Contributor: farid <farid at archlinuc-br.org>
+# Contributor: Archie <Mymaud at gmail.com>
+
+pkgbase=gmic
+pkgname=(gmic gimp-plugin-gmic)
+pkgver=3.0.0
+pkgrel=3
+arch=(x86_64)
+url='https://gmic.eu/'
+license=(custom:CeCILL)
+makedepends=(cmake gimp qt5-base fftw openexr opencv eigen graphicsmagick qt5-tools)
+source=(https://gmic.eu/files/source/gmic_$pkgver.tar.gz)
+sha256sums=('3f056bb9e6dbf0674af4c8dce59f4198172187662f7fbb36cc63ebc8c1b71120')
+
+build() {
+  cmake -B build -S gmic-$pkgver \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DENABLE_DYNAMIC_LINKING=ON \
+    -DBUILD_LIB_STATIC=OFF \
+    -DENABLE_OPENCV=ON
+  cmake --build build
+
+  export LDFLAGS="$LDFLAGS -L../build"
+  cmake -B build-qt -S gmic-$pkgver/gmic-qt \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DENABLE_DYNAMIC_LINKING=ON \
+    -DGMIC_PATH="$srcdir"/gmic-$pkgver/src \
+    -DGMIC_QT_HOST=none
+  cmake --build build-qt
+
+  cmake -B build-gimp -S gmic-$pkgver/gmic-qt \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DENABLE_DYNAMIC_LINKING=ON \
+    -DGMIC_PATH="$srcdir"/gmic-$pkgver/src \
+    -DGMIC_QT_HOST=gimp
+  cmake --build build-gimp
+}
+
+package_gmic() {
+  pkgdesc="GREYC's Magic Image Converter: image processing framework"
+  depends=(graphicsmagick opencv fftw)
+  optdepends=('qt5-base: for the Qt UI')
+
+  DESTDIR="$pkgdir" cmake --install build
+  install -Dm644 gmic-$pkgver/COPYING "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+
+  DESTDIR="$pkgdir" cmake --install build-qt
+
+  install -Dm644 gmic-$pkgver/resources/gmic_cluts.gmz -t "$pkgdir"/usr/share/gmic
+}
+
+package_gimp-plugin-gmic() {
+  pkgdesc="Gimp plugin for the G'MIC image processing framework"
+  depends=(gimp gmic qt5-base)
+
+  DESTDIR="$pkgdir" cmake --install build-gimp
+  install -Dm644 gmic-$pkgver/COPYING "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}