[arch-commits] Commit in haskell-hls-plugin-api/repos (2 files)

[Felix Yan]

    Date: Wednesday, December 29, 2021 @ 02:02:51
  Author: felixonmars
Revision: 1086662

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-hls-plugin-api/repos/community-staging-x86_64/
  haskell-hls-plugin-api/repos/community-staging-x86_64/PKGBUILD
    (from rev 1086661, haskell-hls-plugin-api/trunk/PKGBUILD)

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Copied: haskell-hls-plugin-api/repos/community-staging-x86_64/PKGBUILD (from rev 1086661, haskell-hls-plugin-api/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-12-29 02:02:51 UTC (rev 1086662)
@@ -0,0 +1,50 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=hls-plugin-api
+pkgname=haskell-hls-plugin-api
+pkgver=1.2.0.0
+pkgrel=30
+pkgdesc="Haskell Language Server API for plugin communication"
+url="https://github.com/haskell/haskell-language-server/hls-plugin-api"
+license=("Apache")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-diff' 'haskell-aeson' 'haskell-data-default' 'haskell-dependent-map'
+         'haskell-dependent-sum' 'haskell-dlist' 'haskell-ghc' 'haskell-ghc-api-compat'
+         'haskell-hashable' 'haskell-hls-graph' 'haskell-hslogger' 'haskell-lens' 'haskell-lsp'
+         'haskell-optparse-applicative' 'haskell-opentelemetry' 'haskell-regex-tdfa'
+         'haskell-unordered-containers')
+makedepends=('ghc' 'uusi')
+source=("https://hackage.haskell.org/packages/archive/$_hkgname/$pkgver/$_hkgname-$pkgver.tar.gz")
+sha512sums=('71e6addec81ba84bb26d8048107cb60a94ddb01ac4879640ec7ab7db8586515f1e0419db79e5fe3d8bfc0b37679f307c0c6e97e83739723439c48b14d2124d96')
+
+prepare() {
+  cd $_hkgname-$pkgver
+  gen-setup
+  uusi -u ghc-api-compat $_hkgname.cabal
+}
+
+build() {
+  cd $_hkgname-$pkgver
+
+  runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+    --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+    --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm \
+    --ghc-option=-optl-Wl\,-z\,relro\,-z\,now \
+    --ghc-option='-pie'
+
+  runhaskell Setup build $MAKEFLAGS
+  runhaskell Setup register --gen-script
+  runhaskell Setup unregister --gen-script
+  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+  cd $_hkgname-$pkgver
+
+  install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+  install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+  runhaskell Setup copy --destdir="$pkgdir"
+  install -D -m644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
+  rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}