[arch-commits] Commit in fq/repos (community-x86_64 community-x86_64/PKGBUILD)

[Orhun Parmaksiz]

    Date: Wednesday, December 29, 2021 @ 10:07:34
  Author: orhun
Revision: 1086864

archrelease: copy trunk to community-x86_64

Added:
  fq/repos/community-x86_64/
  fq/repos/community-x86_64/PKGBUILD
    (from rev 1086863, fq/trunk/PKGBUILD)

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Copied: fq/repos/community-x86_64/PKGBUILD (from rev 1086863, fq/trunk/PKGBUILD)
===================================================================
--- community-x86_64/PKGBUILD	                        (rev 0)
+++ community-x86_64/PKGBUILD	2021-12-29 10:07:34 UTC (rev 1086864)
@@ -0,0 +1,45 @@
+# Maintainer: Orhun Parmaksız <orhun at archlinux.org>
+# Contributor: Daniel Milde <daniel at milde dot cz>
+
+pkgname=fq
+pkgver=0.0.2
+pkgrel=2
+pkgdesc="Tool, language and decoders for inspecting binary data"
+arch=('x86_64')
+url="https://github.com/wader/fq"
+license=('MIT')
+depends=('glibc')
+makedepends=('go' 'git')
+source=(${pkgname}-${pkgver}.tar.gz::"${url}/archive/v${pkgver}.tar.gz")
+sha256sums=('1bb7b968ba4ffe6f0dc8b080a2051719caebb96c244606468aecb2786640937b')
+
+prepare() {
+  cd "${pkgname}-${pkgver}"
+  mkdir -p dist/
+}
+
+build() {
+  cd "${pkgname}-${pkgver}"
+  go build \
+    -trimpath \
+    -buildmode=pie \
+    -mod=readonly \
+    -modcacherw \
+    -ldflags "-linkmode external -extldflags \"${LDFLAGS}\" ${_BUILDINFO}" \
+    -o dist/fq \
+    .
+}
+
+check() {
+  cd "${pkgname}-${pkgver}"
+  go test ./...
+}
+
+package() {
+  cd "${pkgname}-${pkgver}"
+  install -Dm 755 "dist/${pkgname}" -t "${pkgdir}/usr/bin"
+  install -Dm 644 LICENSE  -t "${pkgdir}/usr/share/licenses/${pkgname}"
+  install -Dm 644 README.md -t "${pkgdir}/usr/share/doc/${pkgname}"
+}
+
+# vim:set ts=2 sw=2 et: