[arch-commits] Commit in haskell-serialise/repos (2 files)

[Felix Yan]

    Date: Wednesday, December 29, 2021 @ 13:37:01
  Author: felixonmars
Revision: 1087197

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-serialise/repos/community-staging-x86_64/
  haskell-serialise/repos/community-staging-x86_64/PKGBUILD
    (from rev 1087196, haskell-serialise/trunk/PKGBUILD)

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Copied: haskell-serialise/repos/community-staging-x86_64/PKGBUILD (from rev 1087196, haskell-serialise/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-12-29 13:37:01 UTC (rev 1087197)
@@ -0,0 +1,44 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=serialise
+pkgname=haskell-serialise
+pkgver=0.2.4.0
+pkgrel=8
+pkgdesc="A binary serialisation library for Haskell values"
+url="https://github.com/well-typed/cborg"
+license=('BSD')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-cborg' 'haskell-half' 'haskell-hashable' 'haskell-primitive'
+         'haskell-strict' 'haskell-these' 'haskell-unordered-containers' 'haskell-vector')
+makedepends=('ghc' 'haskell-quickcheck' 'haskell-quickcheck-instances' 'haskell-tasty'
+             'haskell-tasty-hunit' 'haskell-tasty-quickcheck')
+source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
+sha512sums=('de575c239ae8802ef8f1342a8a3c3360e83971a9178369cb0e9eaa1698ffe189a51de62ba7b6f4ff25a582f10bf0e346daf39a4e56792ba34d6df550eb34043f')
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test --show-details=direct
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE.txt -t "$pkgdir"/usr/share/licenses/$pkgname/
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE.txt
+}