[arch-commits] Commit in cage/repos (2 files)

[David Runge]

    Date: Wednesday, December 29, 2021 @ 22:10:45
  Author: dvzrv
Revision: 1087674

archrelease: copy trunk to community-staging-x86_64

Added:
  cage/repos/community-staging-x86_64/
  cage/repos/community-staging-x86_64/PKGBUILD
    (from rev 1087673, cage/trunk/PKGBUILD)

----------+
 PKGBUILD |   43 +++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)

Copied: cage/repos/community-staging-x86_64/PKGBUILD (from rev 1087673, cage/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-12-29 22:10:45 UTC (rev 1087674)
@@ -0,0 +1,43 @@
+# Maintainer: David Runge <dvzrv at archlinux.org>
+# Maintainer: Brett Cornwall <ainola at archlinux.org>
+
+pkgname=cage
+pkgver=0.1.4
+pkgrel=2
+pkgdesc="A kiosk compositor for Wayland"
+arch=(x86_64)
+url="https://www.hjdskes.nl/projects/cage/"
+license=(MIT)
+depends=(glibc polkit wayland)
+makedepends=(git libxkbcommon meson pixman scdoc wayland-protocols
+wlroots xorg-server-xwayland)
+optdepends=('xorg-server-xwayland: X11 support')
+source=("${pkgname}::git+https://github.com/Hjdskes/${pkgname}.git#tag=v${pkgver}?signed")
+sha512sums=('SKIP')
+validpgpkeys=('13B6A35E9FD677D02CD68DBE37C445296EBC43B1') # Jente Hidskes <dev at hjdskes.nl>
+
+prepare() {
+  cd "${pkgname}"
+  # add support for wlroots 0.15.0
+  git cherry-pick -n 1a3ab3eb3ad0f4a1addb8f9a9427d8b369b19511
+  git cherry-pick -n 8385b62a9b31028fa356cc4130baebc8b6f4adec
+  git cherry-pick -n 388d60d6b88733330fb83dd440051ee805cc7ec7
+  git cherry-pick -n 395189fb051ed722c7b10b6cb11caa8f6904079c
+}
+
+build() {
+  arch-meson -Dxwayland=true build "$pkgname"
+  ninja -C build
+}
+
+check() {
+  ninja -C build test
+}
+
+package() {
+  depends+=(libwlroots.so libxkbcommon.so libpixman-1.so)
+
+  DESTDIR="${pkgdir}" meson install -C build
+  install -vDm 644 "$pkgname/README.md" -t "${pkgdir}/usr/share/doc/${pkgname}"
+  install -vDm 644 "$pkgname/LICENSE" -t "${pkgdir}/usr/share/licenses/${pkgname}"
+}