[arch-commits] Commit in lib32-e2fsprogs/repos (2 files)

[Christian Hesse]

    Date: Thursday, December 30, 2021 @ 19:34:49
  Author: eworm
Revision: 1088837

archrelease: copy trunk to multilib-testing-x86_64

Added:
  lib32-e2fsprogs/repos/multilib-testing-x86_64/
  lib32-e2fsprogs/repos/multilib-testing-x86_64/PKGBUILD
    (from rev 1088836, lib32-e2fsprogs/trunk/PKGBUILD)

----------+
 PKGBUILD |   46 ++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)

Copied: lib32-e2fsprogs/repos/multilib-testing-x86_64/PKGBUILD (from rev 1088836, lib32-e2fsprogs/trunk/PKGBUILD)
===================================================================
--- multilib-testing-x86_64/PKGBUILD	                        (rev 0)
+++ multilib-testing-x86_64/PKGBUILD	2021-12-30 19:34:49 UTC (rev 1088837)
@@ -0,0 +1,46 @@
+# Maintainer:  Ionut Biru <ibiru at archlinux.org>
+# Contributor: mightyjaym <jm.ambrosino at free.fr>
+# Contributor: Mikko Seppälä <t-r-a-y at mbnet.fi>
+
+pkgname=lib32-e2fsprogs
+pkgver=1.46.5
+pkgrel=1
+pkgdesc='Ext2/3/4 filesystem libraries (32-bit)'
+arch=('x86_64')
+license=('GPL' 'LGPL' 'MIT')
+url='http://e2fsprogs.sourceforge.net'
+depends=('lib32-glibc' 'e2fsprogs')
+makedepends=('bc' 'lib32-util-linux' 'gcc-multilib')
+provides=('libcom_err.so'
+          'libe2p.so'
+          'libext2fs.so'
+          'libss.so')
+validpgpkeys=('3AB057B7E78D945C8C5591FBD36F769BC11804F0') # Theodore Ts'o <tytso at mit.edu>
+source=("https://www.kernel.org/pub/linux/kernel/people/tytso/e2fsprogs/v${pkgver}/e2fsprogs-${pkgver}.tar."{xz,sign})
+sha256sums=('2f16c9176704cf645dc69d5b15ff704ae722d665df38b2ed3cfc249757d8d81e'
+            'SKIP')
+
+build() {
+  export CC='gcc -m32'
+  export CXX='g++ -m32'
+  export PKG_CONFIG_PATH='/usr/lib32/pkgconfig'
+
+  cd "${srcdir}/e2fsprogs-${pkgver}"
+
+  ./configure --prefix=/usr \
+    --libdir=/usr/lib32 \
+    --with-root-prefix='' \
+    --enable-elf-shlibs \
+    --disable-{debugfs,imager,resizer,fsck,uuidd,libuuid,libblkid}
+  make
+}
+
+package() {
+  cd "${srcdir}/e2fsprogs-${pkgver}"
+
+  make DESTDIR="${pkgdir}" install-libs
+
+  rm -rf "${pkgdir}"/usr/{bin,include,share}
+  mkdir -p "${pkgdir}"/usr/share/licenses
+  ln -s e2fsprogs "${pkgdir}/usr/share/licenses/${pkgname}"
+}