[arch-commits] Commit in lua-cliargs/repos/community-any (PKGBUILD PKGBUILD)

[Caleb Maclennan]

    Date: Thursday, December 30, 2021 @ 23:03:42
  Author: alerque
Revision: 1089024

archrelease: copy trunk to community-any

Added:
  lua-cliargs/repos/community-any/PKGBUILD
    (from rev 1089021, lua-cliargs/trunk/PKGBUILD)
Deleted:
  lua-cliargs/repos/community-any/PKGBUILD

----------+
 PKGBUILD |   99 +++++++++++++++++++++++++++++++++----------------------------
 1 file changed, 55 insertions(+), 44 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2021-12-30 23:03:38 UTC (rev 1089023)
+++ PKGBUILD	2021-12-30 23:03:42 UTC (rev 1089024)
@@ -1,44 +0,0 @@
-# Maintainer: Caleb Maclennan <caleb at alerque.com>
-
-pkgbase=lua-cliargs
-_rockname=${pkgbase#lua-}
-pkgname=("$pkgbase" "lua51-$_rockname" "lua52-$_rockname" "lua53-$_rockname")
-pkgver=3.0
-pkgrel=6
-_rockrel=2
-pkgdesc='A command-line argument parser'
-arch=(any)
-url="https://github.com/amireh/${pkgbase/-/_}"
-license=(MIT)
-makedepends=(lua
-             lua51
-             lua52
-             lua53
-             luarocks)
-_archive="${pkgbase/-/_}-$pkgver-$_rockrel"
-source=("$_archive.tar.gz::$url/archive/v$pkgver-$_rockrel.tar.gz")
-sha256sums=('971d6f1440a55bdf9db581d4b2bcbf472a301d76f696a0d0ed9423957c7d176e')
-
-_package() {
-	cd "$_archive"
-	depends=("${pkgname%-*}")
-	luarocks --lua-version="$1" --tree="$pkgdir/usr/" \
-		make --deps-mode=none --no-manifest "${pkgbase/-/_}-$pkgver-$_rockrel.rockspec"
-    install -Dm0644 -t "$pkgdir/usr/share/licenses/$pkgname/" LICENSE
-}
-
-package_lua-cliargs() {
-	_package 5.4
-}
-
-package_lua51-cliargs() {
-	_package 5.1
-}
-
-package_lua52-cliargs() {
-	_package 5.2
-}
-
-package_lua53-cliargs() {
-	_package 5.3
-}

Copied: lua-cliargs/repos/community-any/PKGBUILD (from rev 1089021, lua-cliargs/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2021-12-30 23:03:42 UTC (rev 1089024)
@@ -0,0 +1,55 @@
+# Maintainer: Caleb Maclennan <caleb at alerque.com>
+
+pkgbase=lua-cliargs
+_rockname=${pkgbase#lua-}
+pkgname=("$pkgbase" "lua51-$_rockname" "lua52-$_rockname" "lua53-$_rockname")
+pkgver=3.0
+pkgrel=7
+_rockrel=2
+pkgdesc='A command-line argument parser'
+arch=(any)
+url="https://github.com/amireh/${pkgbase/-/_}"
+license=(MIT)
+makedepends=(lua
+             lua51
+             lua52
+             lua53
+             luarocks)
+checkdepends=(busted
+              lua-inifile
+              lua-yaml)
+_optdepends=('inifile: load config file from INI'
+             'yaml: load config file from YAML')
+_archive="${pkgbase/-/_}-$pkgver-$_rockrel"
+source=("$url/archive/v$pkgver/$_archive.tar.gz")
+sha256sums=('971d6f1440a55bdf9db581d4b2bcbf472a301d76f696a0d0ed9423957c7d176e')
+
+check() {
+	cd "$_archive"
+	busted
+}
+
+_package() {
+	cd "$_archive"
+	depends=("${pkgname%-*}")
+	optdepends=("${_optdepends[@]/#/${pkgname%-*}-}")
+	luarocks --lua-version="$1" --tree="$pkgdir/usr/" \
+		make --deps-mode=none --no-manifest "${pkgbase/-/_}-$pkgver-$_rockrel.rockspec"
+	install -Dm0644 -t "$pkgdir/usr/share/licenses/$pkgname/" LICENSE
+}
+
+package_lua-cliargs() {
+	_package 5.4
+}
+
+package_lua51-cliargs() {
+	_package 5.1
+}
+
+package_lua52-cliargs() {
+	_package 5.2
+}
+
+package_lua53-cliargs() {
+	_package 5.3
+}