[arch-commits] Commit in haskell-chell-quickcheck/repos (2 files)

[Felix Yan]

    Date: Friday, December 31, 2021 @ 04:33:18
  Author: felixonmars
Revision: 1089456

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-chell-quickcheck/repos/community-staging-x86_64/
  haskell-chell-quickcheck/repos/community-staging-x86_64/PKGBUILD
    (from rev 1089455, haskell-chell-quickcheck/trunk/PKGBUILD)

----------+
 PKGBUILD |   42 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)

Copied: haskell-chell-quickcheck/repos/community-staging-x86_64/PKGBUILD (from rev 1089455, haskell-chell-quickcheck/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-12-31 04:33:18 UTC (rev 1089456)
@@ -0,0 +1,42 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=chell-quickcheck
+pkgname=haskell-chell-quickcheck
+pkgver=0.2.5.2
+pkgrel=151
+pkgdesc="QuickCheck support for the Chell testing library"
+url="https://github.com/typeclasses/chell"
+license=('MIT')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-chell' 'haskell-quickcheck' 'haskell-random')
+makedepends=('ghc')
+source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
+sha512sums=('d17b8aeb19adc08debdfccaeceabb480fcbf82ba47c5e805f326f26be8c3266b741c52ab1ab13042b13aaa865ae355812ff067f3a46ff8186cef232143fa8efa')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    sed -i 's/< *2.13/<3/' $_hkgname.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 "license.txt" "${pkgdir}/usr/share/licenses/${pkgname}/license.txt"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/license.txt"
+}