[arch-commits] Commit in (4 files)

[Justin Kromlinger]

    Date: Friday, December 31, 2021 @ 15:37:09
  Author: hashworks
Revision: 1090386

Initial commit

Added:
  opensearch-dashboards-observability-plugin/
  opensearch-dashboards-observability-plugin/repos/
  opensearch-dashboards-observability-plugin/trunk/
  opensearch-dashboards-observability-plugin/trunk/PKGBUILD

----------+
 PKGBUILD |   52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

Added: opensearch-dashboards-observability-plugin/trunk/PKGBUILD
===================================================================
--- opensearch-dashboards-observability-plugin/trunk/PKGBUILD	                        (rev 0)
+++ opensearch-dashboards-observability-plugin/trunk/PKGBUILD	2021-12-31 15:37:09 UTC (rev 1090386)
@@ -0,0 +1,52 @@
+# Maintainer: Justin Kromlinger <hashworks at archlinux.org>
+
+pkgname='opensearch-dashboards-observability-plugin'
+_pluginname='observability-dashboards-plugin'
+pkgver=1.2.2.0
+_dashboardsver=1.2.0
+pkgrel=1
+pkgdesc='OpenSearch Dashboards Observability Plugin'
+url='https://opensearch.org/docs/latest/observability/index/'
+arch=('x86_64')
+license=('Apache')
+depends=('opensearch-dashboards' 'gnuplot')
+makedepends=('yarn' 'python' 'git')
+options=('!strip' 'emptydirs')
+source=(
+  "git+https://github.com/opensearch-project/observability.git#tag=${pkgver}"
+  "git+https://github.com/opensearch-project/OpenSearch-Dashboards.git#tag=${_dashboardsver}"
+)
+sha256sums=(
+  'SKIP'
+  'SKIP'
+)
+
+prepare() {
+  nodeVersion="$(node -v)"
+  # Yes, you support this version. You just don't know it yet.
+  sed -i "s/    \"node\": \"[0-9\.]*\",/    \"node\": \"${nodeVersion:1}\",/" "OpenSearch-Dashboards/package.json"
+}
+
+build() {
+  mv "observability/dashboards-observability" "OpenSearch-Dashboards/plugins/${_pluginname}"
+  cd "OpenSearch-Dashboards/plugins/${_pluginname}"
+  yarn osd bootstrap
+  yarn build --skip-archive
+}
+
+# TODO: Fix tests
+#check() {
+#  cd "OpenSearch-Dashboards/plugins/${_pluginname}"
+#  yarn test
+#}
+
+package() {
+  install -Dm644 "${srcdir}/observability/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+  install -dm755 "${pkgdir}/usr/share/opensearch-dashboards/plugins/"
+
+  cp -r "${srcdir}/OpenSearch-Dashboards/plugins/${_pluginname}/build/opensearch-dashboards/"* "${pkgdir}/usr/share/opensearch-dashboards/plugins/"
+
+  find "${pkgdir}/usr/share/opensearch-dashboards/plugins" -type d -empty -delete
+}
+
+# vim: ts=2 sw=2 et: