[arch-commits] Commit in (4 files)

[Justin Kromlinger]

    Date: Friday, December 31, 2021 @ 15:39:52
  Author: hashworks
Revision: 1090401

Initial commit

Added:
  opensearch-anomaly-detection-plugin/
  opensearch-anomaly-detection-plugin/repos/
  opensearch-anomaly-detection-plugin/trunk/
  opensearch-anomaly-detection-plugin/trunk/PKGBUILD

----------+
 PKGBUILD |   33 +++++++++++++++++++++++++++++++++
 1 file changed, 33 insertions(+)

Added: opensearch-anomaly-detection-plugin/trunk/PKGBUILD
===================================================================
--- opensearch-anomaly-detection-plugin/trunk/PKGBUILD	                        (rev 0)
+++ opensearch-anomaly-detection-plugin/trunk/PKGBUILD	2021-12-31 15:39:52 UTC (rev 1090401)
@@ -0,0 +1,33 @@
+# Maintainer: Justin Kromlinger <hashworks at archlinux.org>
+
+pkgname=opensearch-anomaly-detection-plugin
+pkgver=1.2.0.0
+pkgrel=1
+pkgdesc="OpenSearch Anomaly Detection Plugin"
+arch=('x86_64')
+url="https://opensearch.org/docs/latest/monitoring-plugins/ad"
+license=('Apache')
+depends=('opensearch')
+makedepends=('java-environment=11' 'unzip')
+source=(
+  "${pkgname}-${pkgver}.tar.gz::https://github.com/opensearch-project/anomaly-detection/archive/${pkgver}.tar.gz"
+)
+sha256sums=('a0499f98d7959a27b935859672cf570966d27c03d27fe0f307d23ddeaa77682e')
+
+build() {
+  cd "anomaly-detection-${pkgver}"
+  export PATH=/usr/lib/jvm/default/bin:$PATH
+  export GRADLE_OPTS="-Dbuild.snapshot=false"
+  # integTest (Reaper) requires JDK 14
+  ./gradlew assemble \
+    --exclude-task ":integTest" \
+    --exclude-task ":jacocoTestReport"
+}
+
+package() {
+  install -dm755 "${pkgdir}/usr/share/opensearch/plugins/opensearch-anomaly-detection"
+  cd "${pkgdir}/usr/share/opensearch/plugins/opensearch-anomaly-detection"
+  unzip "${srcdir}/anomaly-detection-${pkgver}/build/distributions/opensearch-anomaly-detection-${pkgver}.zip"
+
+  install -Dm644 "${srcdir}/anomaly-detection-${pkgver}/LICENSE.txt" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE.txt"
+}