[arch-commits] Commit in (4 files)

[Justin Kromlinger]

    Date: Friday, December 31, 2021 @ 15:41:20
  Author: hashworks
Revision: 1090407

Initial commit

Added:
  opensearch-cross-cluster-replication-plugin/
  opensearch-cross-cluster-replication-plugin/repos/
  opensearch-cross-cluster-replication-plugin/trunk/
  opensearch-cross-cluster-replication-plugin/trunk/PKGBUILD

----------+
 PKGBUILD |   33 +++++++++++++++++++++++++++++++++
 1 file changed, 33 insertions(+)

Added: opensearch-cross-cluster-replication-plugin/trunk/PKGBUILD
===================================================================
--- opensearch-cross-cluster-replication-plugin/trunk/PKGBUILD	                        (rev 0)
+++ opensearch-cross-cluster-replication-plugin/trunk/PKGBUILD	2021-12-31 15:41:20 UTC (rev 1090407)
@@ -0,0 +1,33 @@
+# Maintainer: Justin Kromlinger <hashworks at archlinux.org>
+
+pkgname=opensearch-cross-cluster-replication-plugin
+pkgver=1.2.0.0
+pkgrel=1
+pkgdesc="OpenSearch Cross-Cluster Replication Plugin"
+arch=('x86_64')
+url="https://opensearch.org/docs/latest/replication-plugin"
+license=('Apache')
+depends=('opensearch')
+makedepends=('java-environment=11' 'unzip')
+source=(
+  "${pkgname}-${pkgver}.tar.gz::https://github.com/opensearch-project/cross-cluster-replication/archive/${pkgver}.tar.gz"
+)
+sha256sums=('70d37e7dc2aeeb27e7c6ab7bed8f64752d5e3dae03e352ce3781cf2e0a5adef3')
+
+build() {
+  cd "cross-cluster-replication-${pkgver}"
+  export PATH=/usr/lib/jvm/default/bin:$PATH
+  export GRADLE_OPTS="-Dbuild.snapshot=false"
+  # integTest (Reaper) requires JDK 14
+  ./gradlew assemble \
+    --exclude-task ":integTest" \
+    --exclude-task ":jacocoTestReport"
+}
+
+package() {
+  install -dm755 "${pkgdir}/usr/share/opensearch/plugins/opensearch-cross-cluster-replication"
+  cd "${pkgdir}/usr/share/opensearch/plugins/opensearch-cross-cluster-replication"
+  unzip "${srcdir}/cross-cluster-replication-${pkgver}/build/distributions/opensearch-cross-cluster-replication-${pkgver}.zip"
+
+  install -Dm644 "${srcdir}/cross-cluster-replication-${pkgver}/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}