[arch-commits] Commit in (4 files)

Justin Kromlinger hashworks at gemini.archlinux.org
Fri Dec 31 16:13:14 UTC 2021


    Date: Friday, December 31, 2021 @ 16:13:13
  Author: hashworks
Revision: 1090445

Initial commit

Added:
  opensearch-performance-analyzer-plugin/
  opensearch-performance-analyzer-plugin/repos/
  opensearch-performance-analyzer-plugin/trunk/
  opensearch-performance-analyzer-plugin/trunk/PKGBUILD

----------+
 PKGBUILD |   34 ++++++++++++++++++++++++++++++++++
 1 file changed, 34 insertions(+)

Added: opensearch-performance-analyzer-plugin/trunk/PKGBUILD
===================================================================
--- opensearch-performance-analyzer-plugin/trunk/PKGBUILD	                        (rev 0)
+++ opensearch-performance-analyzer-plugin/trunk/PKGBUILD	2021-12-31 16:13:13 UTC (rev 1090445)
@@ -0,0 +1,34 @@
+# Maintainer: Justin Kromlinger <hashworks at archlinux.org>
+
+pkgname=opensearch-performance-analyzer-plugin
+pkgver=1.2.3.0
+_opensearchver=1.2.3
+pkgrel=1
+pkgdesc="OpenSearch Performance Analyzer Plugin"
+arch=('x86_64')
+url="https://opensearch.org/docs/latest/monitoring-plugins/pa"
+license=('Apache')
+depends=('opensearch')
+makedepends=('java-environment=11' 'unzip')
+source=(
+  "${pkgname}-${pkgver}.tar.gz::https://github.com/opensearch-project/performance-analyzer/archive/${pkgver}.tar.gz"
+)
+sha256sums=('8f7fa642554d82a3e4374e62503e05c385f57876ed51c729410713d6d0d89c15')
+
+build() {
+  cd "performance-analyzer-${pkgver}"
+  export PATH=/usr/lib/jvm/default/bin:$PATH
+  export GRADLE_OPTS="-Dbuild.snapshot=false -Dopensearch.version=${_opensearchver}"
+  # integTest (Reaper) requires JDK 14
+  ./gradlew assemble \
+    --exclude-task ":integTest" \
+    --exclude-task ":jacocoTestReport"
+}
+
+package() {
+  install -dm755 "${pkgdir}/usr/share/opensearch/plugins/opensearch-performance-analyzer"
+  cd "${pkgdir}/usr/share/opensearch/plugins/opensearch-performance-analyzer"
+  unzip "${srcdir}/performance-analyzer-${pkgver}/build/distributions/opensearch-performance-analyzer-${pkgver}.zip"
+
+  install -Dm644 "${srcdir}/performance-analyzer-${pkgver}/LICENSE.txt" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE.txt"
+}



More information about the arch-commits mailing list