[arch-commits] Commit in haskell-criterion/repos (2 files)

[Felix Yan]

    Date: Monday, February 1, 2021 @ 02:04:47
  Author: felixonmars
Revision: 839120

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-criterion/repos/community-staging-x86_64/
  haskell-criterion/repos/community-staging-x86_64/PKGBUILD
    (from rev 839119, haskell-criterion/trunk/PKGBUILD)

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Copied: haskell-criterion/repos/community-staging-x86_64/PKGBUILD (from rev 839119, haskell-criterion/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-02-01 02:04:47 UTC (rev 839120)
@@ -0,0 +1,50 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=criterion
+pkgname=haskell-criterion
+pkgver=1.5.9.0
+pkgrel=37
+pkgdesc="Robust, reliable performance measurement and analysis"
+url="http://www.serpentine.com/criterion"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-ansi-wl-pprint' 'haskell-base-compat-batteries'
+         'haskell-binary-orphans' 'haskell-cassava' 'haskell-code-page'
+         'haskell-criterion-measurement' 'haskell-glob' 'haskell-js-chart'
+         'haskell-microstache' 'haskell-mwc-random' 'haskell-optparse-applicative'
+         'haskell-statistics' 'haskell-transformers-compat' 'haskell-vector'
+         'haskell-vector-algorithms')
+makedepends=('ghc' 'haskell-base-compat' 'haskell-hunit' 'haskell-quickcheck' 'haskell-tasty'
+             'haskell-tasty-hunit' 'haskell-tasty-quickcheck')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('ba8550073977ac829d35e327bc976a6a914694d2e9eb29f25c40811ec4064249dba746ac7a3df1b21532ca64c62375d9b35c201c7e259801f21ccde883647ca8')
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir="$pkgname" --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -f-fast -f-embed-data-files
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}