[arch-commits] Commit in skopeo/repos (2 files)

Christian Hesse eworm at archlinux.org
Tue Feb 2 20:04:31 UTC 2021


    Date: Tuesday, February 2, 2021 @ 20:04:30
  Author: eworm
Revision: 841509

archrelease: copy trunk to community-staging-x86_64

Added:
  skopeo/repos/community-staging-x86_64/
  skopeo/repos/community-staging-x86_64/PKGBUILD
    (from rev 841508, skopeo/trunk/PKGBUILD)

----------+
 PKGBUILD |   38 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 38 insertions(+)

Copied: skopeo/repos/community-staging-x86_64/PKGBUILD (from rev 841508, skopeo/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-02-02 20:04:30 UTC (rev 841509)
@@ -0,0 +1,38 @@
+# Maintainer: Morten Linderud <foxboron at archlinux.org>
+# Maintainer: Bartłomiej Piotrowski <bpiotrowski at archlinux.org>
+
+pkgname=skopeo
+pkgver=1.2.1
+pkgrel=2
+pkgdesc='A command line utility for various operations on container images and image repositories.'
+arch=(x86_64)
+url='https://github.com/projectatomic/skopeo'
+license=(APACHE)
+depends=(gpgme device-mapper containers-common)
+makedepends=(go go-md2man btrfs-progs git systemd)
+_commit=bdb117ded6d37f0a6b0a2e28ba3213c20264ab43	#refs/tags/v1.2.1
+source=(git+$url#commit=$_commit)
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/^v//;s/-/+/g'
+}
+
+build() {
+  cd $pkgname
+  export CGO_LDFLAGS="${LDFLAGS}"
+  export CGO_CFLAGS="${CFLAGS}"
+  export CGO_CPPFLAGS="${CPPFLAGS}"
+  export CGO_CXXFLAGS="${CXXFLAGS}"
+  export GOFLAGS="-buildmode=pie -trimpath -mod=readonly -modcacherw"
+  make bin/skopeo BUILDTAGS='containers_image_ostree_stub'
+  make docs
+}
+
+package() {
+  cd $pkgname
+  make DESTDIR="$pkgdir" install
+  rm -rf "${pkgdir}/etc/containers/registries.d"
+  rm "${pkgdir}/etc/containers/policy.json"
+}


More information about the arch-commits mailing list