[arch-commits] Commit in podman/repos (2 files)
Christian Hesse
eworm at archlinux.org
Tue Feb 2 20:11:42 UTC 2021
Date: Tuesday, February 2, 2021 @ 20:11:42
Author: eworm
Revision: 841521
archrelease: copy trunk to community-staging-x86_64
Added:
podman/repos/community-staging-x86_64/
podman/repos/community-staging-x86_64/PKGBUILD
(from rev 841520, podman/trunk/PKGBUILD)
----------+
PKGBUILD | 58 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 58 insertions(+)
Copied: podman/repos/community-staging-x86_64/PKGBUILD (from rev 841520, podman/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD (rev 0)
+++ community-staging-x86_64/PKGBUILD 2021-02-02 20:11:42 UTC (rev 841521)
@@ -0,0 +1,58 @@
+# Maintainer: Morten Linderud <foxboron at archlinux.org>
+# Contributor: David Runge <dvzrv at archlinux.org>
+# Contributor: Bartłomiej Piotrowski <bpiotrowski at archlinux.org>
+
+pkgbase=podman
+pkgname=(podman podman-docker)
+pkgver=2.2.1
+pkgrel=2
+pkgdesc='Tool and library for running OCI-based containers in pods'
+arch=(x86_64)
+url='https://github.com/containers/libpod'
+license=(Apache)
+depends=(cni-plugins conmon containers-common device-mapper iptables libseccomp
+runc slirp4netns libsystemd fuse-overlayfs)
+makedepends=(btrfs-progs go go-md2man git gpgme systemd)
+source=("git+$url#tag=v$pkgver?signed")
+validpgpkeys=('B7DBDCA456F7335E91F1C25CD3624C551D0515C4')
+sha256sums=('SKIP')
+
+pkgver() {
+ cd libpod
+ git describe --tags | sed 's/^v//;s/-/+/g'
+}
+
+build() {
+ export BUILDTAGS='seccomp varlink systemd'
+ export CGO_CPPFLAGS="${CPPFLAGS}"
+ export CGO_CFLAGS="${CFLAGS}"
+ export CGO_CXXFLAGS="${CXXFLAGS}"
+ export CGO_LDFLAGS="${LDFLAGS}"
+ export GOFLAGS="-buildmode=pie -trimpath"
+
+ cd libpod
+ go generate ./pkg/varlink/...
+ make EXTRA_LDFLAGS='-s -w -linkmode=external'
+}
+
+package_podman() {
+ depends+=('libgpgme.so')
+ optdepends+=('podman-docker: for Docker-compatible CLI'
+ 'btrfs-progs: support btrfs backend devices'
+ 'catatonit: --init flag support'
+ 'crun: support for unified cgroupsv2')
+
+ cd libpod
+ make install install.completions DESTDIR="$pkgdir" PREFIX=/usr
+ # remove man pages provided by containers-common
+ rm -rvf "${pkgdir}/usr/share/man/man5"
+}
+
+package_podman-docker() {
+ pkgdesc='Emulate Docker CLI using podman'
+ depends=(podman)
+ conflicts=(docker)
+
+ cd libpod
+ make install.docker DESTDIR="$pkgdir" PREFIX=/usr
+}
More information about the arch-commits
mailing list