[arch-commits] Commit in libldm/repos (3 files)

Christian Hesse eworm at archlinux.org
Tue Feb 2 20:14:03 UTC 2021


    Date: Tuesday, February 2, 2021 @ 20:14:02
  Author: eworm
Revision: 841525

archrelease: copy trunk to community-staging-x86_64

Added:
  libldm/repos/community-staging-x86_64/
  libldm/repos/community-staging-x86_64/PKGBUILD
    (from rev 841524, libldm/trunk/PKGBUILD)
  libldm/repos/community-staging-x86_64/ldmtool.service
    (from rev 841524, libldm/trunk/ldmtool.service)

-----------------+
 PKGBUILD        |   64 ++++++++++++++++++++++++++++++++++++++++++++++++++++++
 ldmtool.service |   13 ++++++++++
 2 files changed, 77 insertions(+)

Copied: libldm/repos/community-staging-x86_64/PKGBUILD (from rev 841524, libldm/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-02-02 20:14:02 UTC (rev 841525)
@@ -0,0 +1,64 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Contributor: Chris Severance <aur.severach at spamgourmet.com>
+# Contributor: Neal Buchanan <neal.buchanan at gmx.com>
+
+pkgname=libldm
+pkgver=0.2.4.r22.63883d8
+pkgrel=2
+pkgdesc='A tool and library for managing Microsoft Windows Dynamic Disks'
+arch=(x86_64)
+url=https://github.com/mdbooth/libldm
+license=(
+  GPL3
+  LGPL3
+)
+depends=(
+  device-mapper
+  glib2
+  json-glib
+  libreadline.so
+  libuuid.so
+  zlib
+)
+makedepends=(
+  git
+  systemd
+  gtk-doc
+)
+provides=(
+  ldmtool
+  libldm-1.0.so
+)
+conflicts=(ldmtool)
+_commit=63883d8151cbdbf0714332984c41c7fb291dea67
+source=(
+  git+https://github.com/mdbooth/libldm.git#commit=${_commit}
+  ldmtool.service
+)
+b2sums=('SKIP'
+        'fa03762f3642959b8abd50e62f79cc23e0dfca49c7c7d661c38d49fd5282d5bd95ccf5b66562a7b005657312b4f4f72e92c4e75365f007ca09e8199b7ba9802a')
+
+pkgver() {
+  cd libldm
+
+  git describe --tags | sed 's/^libldm-//; s/-/.r/; s/-g/./'
+}
+
+prepare() {
+  cd libldm
+  autoreconf -fiv
+}
+
+build() {
+  cd libldm
+  ./configure \
+    --prefix=/usr
+  make
+}
+
+package() {
+  make DESTDIR="${pkgdir}" -C libldm install
+  install -Dm 644 ldmtool.service -t "${pkgdir}"/usr/lib/systemd/system/
+}
+
+# vim: ts=2 sw=2 et:

Copied: libldm/repos/community-staging-x86_64/ldmtool.service (from rev 841524, libldm/trunk/ldmtool.service)
===================================================================
--- community-staging-x86_64/ldmtool.service	                        (rev 0)
+++ community-staging-x86_64/ldmtool.service	2021-02-02 20:14:02 UTC (rev 841525)
@@ -0,0 +1,13 @@
+[Unit]
+Description=Windows Dynamic Disk Mount
+Before=local-fs-pre.target
+DefaultDependencies=no
+
+[Service]
+Type=simple
+User=root
+ExecStart=/usr/bin/ldmtool create all
+
+[Install]
+WantedBy=local-fs-pre.target
+


More information about the arch-commits mailing list