[arch-commits] Commit in pandoc/repos (2 files)

Felix Yan felixonmars at archlinux.org
Thu Feb 4 18:35:21 UTC 2021


    Date: Thursday, February 4, 2021 @ 18:35:20
  Author: felixonmars
Revision: 844771

archrelease: copy trunk to community-staging-x86_64

Added:
  pandoc/repos/community-staging-x86_64/
  pandoc/repos/community-staging-x86_64/PKGBUILD
    (from rev 844770, pandoc/trunk/PKGBUILD)

----------+
 PKGBUILD |   70 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 70 insertions(+)

Copied: pandoc/repos/community-staging-x86_64/PKGBUILD (from rev 844770, pandoc/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-02-04 18:35:20 UTC (rev 844771)
@@ -0,0 +1,70 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+pkgname=pandoc
+pkgver=2.11.3
+pkgrel=19
+pkgdesc='Conversion between markup formats'
+url='https://pandoc.org'
+license=('GPL')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-http' 'haskell-juicypixels' 'haskell-sha' 'haskell-aeson'
+         'haskell-aeson-pretty' 'haskell-attoparsec' 'haskell-base64-bytestring'
+         'haskell-blaze-html' 'haskell-blaze-markup' 'haskell-case-insensitive'
+         'haskell-citeproc' 'haskell-commonmark' 'haskell-commonmark-extensions'
+         'haskell-commonmark-pandoc' 'haskell-connection' 'haskell-data-default' 'haskell-doclayout'
+         'haskell-doctemplates' 'haskell-emojis' 'haskell-file-embed' 'haskell-glob'
+         'haskell-haddock-library' 'haskell-ipynb' 'haskell-jira-wiki-markup' 'haskell-skylighting'
+         'haskell-skylighting-core' 'haskell-hslua' 'haskell-hslua-module-system'
+         'haskell-hslua-module-text' 'haskell-http-client' 'haskell-syb' 'haskell-hsyaml'
+         'haskell-http-client-tls' 'haskell-http-types' 'haskell-safe' 'haskell-split'
+         'haskell-texmath' 'haskell-network' 'haskell-pandoc-types' 'haskell-random'
+         'haskell-scientific' 'haskell-tagsoup' 'haskell-temporary' 'haskell-text-conversions'
+         'haskell-network-uri' 'haskell-unicode-transforms' 'haskell-unordered-containers'
+         'haskell-zip-archive' 'haskell-xml' 'haskell-zlib')
+optdepends=('pandoc-citeproc: for citation rendering with pandoc-citeproc filter'
+            'pandoc-crossref: for numbering figures, equations, tables and cross-references to them with pandoc-crossref filter'
+            'texlive-core: for pdf output')
+conflicts=('haskell-pandoc')
+replaces=('haskell-pandoc')
+makedepends=('ghc' 'uusi' 'haskell-diff' 'haskell-tasty' 'haskell-tasty-hunit' 'haskell-tasty-lua'
+             'haskell-tasty-quickcheck' 'haskell-tasty-golden' 'haskell-quickcheck'
+             'haskell-executable-path')
+source=("https://hackage.haskell.org/packages/archive/${pkgname}/${pkgver}/${pkgname}-${pkgver}.tar.gz")
+sha512sums=('2c37643164223a5c2816b4e5a8520131ccb677072a2373ad4ea7d332b40f8a9f0c48e7981aa4fb3d48e1fe9c2be2f239246a268cb420b6756f727c2e58f0529f')
+
+prepare() {
+    cd $pkgname-$pkgver
+    uusi -u base64-bytestring -u random $pkgname.cabal
+
+    # TODO: find a better solution
+    sed -i "s|let env' = dynlibEnv ++ |let env' = dynlibEnv ++ [(\"LD_LIBRARY_PATH\", \"$PWD/dist/build\")] ++ |" test/Tests/Command.hs
+}
+
+build() {
+    cd $pkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgbase}" --datasubdir="$pkgname" --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -f-trypandoc -f-embed_data_files -f-static
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $pkgname-$pkgver
+    LC_CTYPE=en_US.UTF-8 runhaskell Setup test || echo "Tests failed"
+}
+
+package() {
+    cd $pkgname-$pkgver
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    rm "${pkgdir}/usr/share/doc/${pkgname}/COPYING.md"
+    install -Dm644 man/pandoc.1 -t "${pkgdir}"/usr/share/man/man1/
+}


More information about the arch-commits mailing list