[arch-commits] Commit in knot-resolver/repos (2 files)

[Daurnimator]

    Date: Friday, February 5, 2021 @ 17:10:30
  Author: daurnimator
Revision: 846233

archrelease: copy trunk to community-x86_64

Added:
  knot-resolver/repos/community-x86_64/
  knot-resolver/repos/community-x86_64/PKGBUILD
    (from rev 846232, knot-resolver/trunk/PKGBUILD)

----------+
 PKGBUILD |   56 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)

Copied: knot-resolver/repos/community-x86_64/PKGBUILD (from rev 846232, knot-resolver/trunk/PKGBUILD)
===================================================================
--- community-x86_64/PKGBUILD	                        (rev 0)
+++ community-x86_64/PKGBUILD	2021-02-05 17:10:30 UTC (rev 846233)
@@ -0,0 +1,56 @@
+# Maintainer: Daurnimator <daurnimator at archlinux.org>
+# Contributor: Tomas Krizek <tomas.krizek at nic.cz>
+# Contributor: Ondřej Surý <ondrej at sury.org>
+
+pkgname=knot-resolver
+pkgver=5.2.1
+pkgrel=2
+pkgdesc='Caching DNSSEC-validating DNS resolver'
+arch=('x86_64')
+url='https://www.knot-resolver.cz/'
+license=('GPL3')
+depends=(
+    'dnssec-anchors'
+    'gnutls'
+    'knot'
+    'libedit'
+    'libuv'
+    'lmdb'
+    'luajit'
+    'libcap-ng'
+    'libnghttp2'
+    'systemd-libs'
+)
+makedepends=(
+    'cmocka'
+    'meson'
+)
+optdepends=(
+    'lua51-basexx: experimental_dot_auth module'
+    'lua51-cqueues: http and dns64 module, policy.rpz() function'
+    # TODO: 'lua51-etcd: etcd module'
+    'lua51-http: http and prefill modules, trust_anchors bootstrap'
+    'lua51-psl: policy.slice_randomize_psl() function'
+)
+backup=('etc/knot-resolver/kresd.conf')
+source=("https://secure.nic.cz/files/${pkgname}/${pkgname}-${pkgver}.tar.xz")
+sha256sums=('aa37b744c400f437acba7a54aebcbdbe722ece743d342cbc39f2dd8087f05826')
+
+build() {
+    cd "${pkgname}-${pkgver}"
+    arch-meson build \
+        -D keyfile_default=/etc/trusted-key.key \
+        -D systemd_files=enabled \
+        -D client=enabled \
+        -D install_kresd_conf=enabled \
+        -D unit_tests=enabled
+    ninja -C build
+}
+
+check() {
+    meson test -C "${pkgname}-${pkgver}/build"
+}
+
+package() {
+    DESTDIR="${pkgdir}" ninja -C "${pkgname}-${pkgver}/build" install
+}