[arch-commits] Commit in haskell-binary-instances/repos (2 files)

Felix Yan felixonmars at archlinux.org
Sat Feb 6 14:00:47 UTC 2021


    Date: Saturday, February 6, 2021 @ 14:00:47
  Author: felixonmars
Revision: 846746

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-binary-instances/repos/community-staging-x86_64/
  haskell-binary-instances/repos/community-staging-x86_64/PKGBUILD
    (from rev 846745, haskell-binary-instances/trunk/PKGBUILD)

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Copied: haskell-binary-instances/repos/community-staging-x86_64/PKGBUILD (from rev 846745, haskell-binary-instances/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-02-06 14:00:47 UTC (rev 846746)
@@ -0,0 +1,47 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=binary-instances
+pkgname=haskell-binary-instances
+pkgver=1.0.1
+pkgrel=41
+pkgdesc="Orphan instances for binary"
+url="https://github.com/phadej/binary-instances"
+license=('BSD')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-binary-orphans' 'haskell-case-insensitive'
+         'haskell-hashable' 'haskell-scientific' 'haskell-tagged' 'haskell-text-binary'
+         'haskell-time-compat' 'haskell-unordered-containers' 'haskell-vector'
+         'haskell-vector-binary-instances')
+makedepends=('ghc' 'haskell-quickcheck' 'haskell-quickcheck-instances' 'haskell-tasty'
+             'haskell-tasty-quickcheck')
+source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
+sha512sums=('8282c33d2f7c6dcbf991482c9ae23f316500a60f251e296f5e92488208eaf5f08460c379698bcebd707a61733a13a7b85601587bab4696a24d9ca56ffed1e66b')
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    # https://github.com/phadej/binary-instances/issues/7
+    runhaskell Setup test || echo "Tests failed"
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}


More information about the arch-commits mailing list