[arch-commits] Commit in haskell-lucid/repos (2 files)

[Felix Yan]

    Date: Monday, February 8, 2021 @ 01:10:21
  Author: felixonmars
Revision: 848642

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-lucid/repos/community-staging-x86_64/
  haskell-lucid/repos/community-staging-x86_64/PKGBUILD
    (from rev 848641, haskell-lucid/trunk/PKGBUILD)

----------+
 PKGBUILD |   48 ++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

Copied: haskell-lucid/repos/community-staging-x86_64/PKGBUILD (from rev 848641, haskell-lucid/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-02-08 01:10:21 UTC (rev 848642)
@@ -0,0 +1,48 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=lucid
+pkgname=haskell-lucid
+pkgver=2.9.12
+pkgrel=93
+pkgdesc="Clear to write, read and edit DSL for HTML"
+url="https://github.com/chrisdone/lucid"
+license=('BSD')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-blaze-builder' 'haskell-hashable' 'haskell-mmorph'
+         'haskell-unordered-containers')
+makedepends=('ghc' 'haskell-bifunctors' 'haskell-hspec' 'haskell-hunit')
+source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
+sha512sums=('d26bd0889032482d91c69f23b237437a9ab133e87143364f9b134434bdd5cc849b6393f837f6096410dae51058a47e444c2d4b04a56e8f4f64d5104732180a54')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    sed -i 's/< *4.14/<5/' $_hkgname.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}