[arch-commits] Commit in (3 files)

[Alexander Rødseth]

    Date: Monday, February 8, 2021 @ 12:03:46
  Author: arodseth
Revision: 848909

Add networkmanager-l2tp, 107 votes on AUR, GPL2 licensed

Added:
  networkmanager-l2tp/
  networkmanager-l2tp/trunk/
  networkmanager-l2tp/trunk/PKGBUILD

----------+
 PKGBUILD |   42 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)

Added: networkmanager-l2tp/trunk/PKGBUILD
===================================================================
--- networkmanager-l2tp/trunk/PKGBUILD	                        (rev 0)
+++ networkmanager-l2tp/trunk/PKGBUILD	2021-02-08 12:03:46 UTC (rev 848909)
@@ -0,0 +1,42 @@
+# Maintainer: Alexander F. Rødseth <xyproto at archlinux.org>
+# Contributor: Miles McLean <mills00013 at gmail.com>
+# Contributor: Andrea Scarpino <andrea at archlinux.org>
+# Contributor: Brad Pitcher <bradpitcher at gmail.com>
+# Contributor: Moritz Lipp <mlq at pwmt.org>
+
+pkgname=networkmanager-l2tp
+pkgver=1.8.6
+_pppver=2.4.8
+pkgrel=1
+pkgdesc='L2TP support for NetworkManager'
+arch=(x86_64)
+url='https://github.com/nm-l2tp/NetworkManager-l2tp'
+license=(GPL2)
+depends=(libnm libsecret nss openssl "ppp=$_pppver" xl2tpd)
+makedepends=(intltool libnma python)
+optdepends=('libreswan: IPSec support (recommended)'
+            'strongswan: IPSec support')
+source=("$pkgname-$pkgver.tar.gz"::"$url/archive/$pkgver.tar.gz")
+sha256sums=('1455b2bc0dd802522e79a176c654d1a19482b6a26d7c3a9c0fce2ee2dbb892e2')
+
+prepare() {
+  ln -sf NetworkManager-l2tp-$pkgver $pkgname
+  cd $pkgname
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+  cd $pkgname
+  ./configure \
+    --localstatedir=/var \
+    --libexecdir=/usr/lib/NetworkManager \
+    --prefix=/usr \
+    --sysconfdir=/etc \
+    --with-pppd-plugin-dir=/usr/lib/pppd/$_pppver
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+  make
+}
+
+package() {
+  make -C $pkgname DESTDIR="$pkgdir" install
+}