[arch-commits] Commit in tang/trunk (PKGBUILD)

[Jonas Witschel]

    Date: Monday, February 8, 2021 @ 16:53:53
  Author: diabonas
Revision: 849394

upgpkg: tang 8-1: upstream release

- Use signed release commit as source
- Upstream switch its build system from Autotools to Meson
- systemd is an (optional) checkdepends to test socket activation

Modified:
  tang/trunk/PKGBUILD

----------+
 PKGBUILD |   32 ++++++++++++++++++++------------
 1 file changed, 20 insertions(+), 12 deletions(-)

Modified: PKGBUILD
===================================================================
--- PKGBUILD	2021-02-08 16:53:49 UTC (rev 849393)
+++ PKGBUILD	2021-02-08 16:53:53 UTC (rev 849394)
@@ -1,28 +1,36 @@
 # Maintainer: Jonas Witschel <diabonas at archlinux.org>
 pkgname=tang
-pkgver=7
-pkgrel=7
+pkgver=8
+_commit=95d482256f2d44bd6819df4e41a278937a9827b5 # git rev-parse "v$pkgver^{}"
+pkgrel=1
 pkgdesc='Server for binding data to network presence'
 arch=('x86_64')
 url='https://github.com/latchset/tang'
 license=('GPL3')
 depends=('http-parser' 'jose')
-makedepends=('asciidoc' 'systemd')
-source=("$url/releases/download/v$pkgver/$pkgname-$pkgver.tar.bz2")
-sha512sums=('dd4187fa6962523ac2a745ef05a27cdf7e5264c595942e63d406d67a1c595e87bd7e74091cb2e16362f369480cdf8e3b4bfe1fee13b9cb73d5308f42c52f138a')
+makedepends=('git' 'asciidoc' 'meson')
+checkdepends=('systemd')
+source=("git+$url.git?signed#commit=$_commit")
+sha512sums=('SKIP')
+validpgpkeys=('7CE2CB3D2AF59FE1EA22F551D0D219ED1F7E762C') # Sergio Correia <scorreia at redhat.com>
 
+pkgver() {
+	cd "$pkgname"
+	git describe --tags | sed 's/^v//;s/\([^-]*-\)g/r\1/;s/-/./g'
+}
+
 build() {
-	cd "$pkgname-$pkgver"
-	./configure --prefix=/usr --libexecdir=/usr/lib --localstatedir=/var
-	make
+	cd "$pkgname"
+	meson --libexecdir=/usr/lib --buildtype=plain build
+	meson compile -C build
 }
 
 check() {
-	cd "$pkgname-$pkgver"
-	make check
+	cd "$pkgname"
+	meson test -C build
 }
 
 package() {
-	cd "$pkgname-$pkgver"
-	make DESTDIR="$pkgdir" install
+	cd "$pkgname"
+	DESTDIR="$pkgdir" meson install -C build
 }