[arch-commits] Commit in haskell-vector-algorithms/repos (2 files)

Felix Yan felixonmars at archlinux.org
Tue Feb 9 19:35:16 UTC 2021


    Date: Tuesday, February 9, 2021 @ 19:35:16
  Author: felixonmars
Revision: 851444

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-vector-algorithms/repos/community-staging-x86_64/
  haskell-vector-algorithms/repos/community-staging-x86_64/PKGBUILD
    (from rev 851443, haskell-vector-algorithms/trunk/PKGBUILD)

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Copied: haskell-vector-algorithms/repos/community-staging-x86_64/PKGBUILD (from rev 851443, haskell-vector-algorithms/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-02-09 19:35:16 UTC (rev 851444)
@@ -0,0 +1,44 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=vector-algorithms
+pkgname=haskell-vector-algorithms
+pkgver=0.8.0.4
+pkgrel=29
+pkgdesc="Efficient algorithms for vector arrays"
+url="https://github.com/erikd/vector-algorithms/"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-primitive' 'haskell-vector')
+makedepends=('ghc' 'haskell-quickcheck')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('da5f52493c7f68df0a2c718724dcac9be758b09b14c8fa913aa328ee4c1286893fb239882018202d0fcd56709364ccddf3d620ff3b886d830102ef52a0868d42')
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -fproperties -f-bench -f-internalchecks -f-unsafechecks -fboundschecks -f-llvm
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}



More information about the arch-commits mailing list