[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Wednesday, February 10, 2021 @ 08:41:11
  Author: felixonmars
Revision: 853412

addpkg: haskell-sqlite-simple 0.4.18.0-1

Added:
  haskell-sqlite-simple/
  haskell-sqlite-simple/repos/
  haskell-sqlite-simple/trunk/
  haskell-sqlite-simple/trunk/PKGBUILD

----------+
 PKGBUILD |   51 +++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)

Added: haskell-sqlite-simple/trunk/PKGBUILD
===================================================================
--- haskell-sqlite-simple/trunk/PKGBUILD	                        (rev 0)
+++ haskell-sqlite-simple/trunk/PKGBUILD	2021-02-10 08:41:11 UTC (rev 853412)
@@ -0,0 +1,51 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=sqlite-simple
+pkgname=haskell-sqlite-simple
+pkgver=0.4.18.0
+pkgrel=1
+pkgdesc="Mid-Level SQLite client library"
+url="http://github.com/nurpax/sqlite-simple"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-only' 'haskell-attoparsec' 'haskell-blaze-builder'
+         'haskell-blaze-textual' 'haskell-direct-sqlite')
+makedepends=('ghc' 'uusi' 'haskell-hunit' 'haskell-base16-bytestring')
+source=("https://hackage.haskell.org/packages/archive/$_hkgname/$pkgver/$_hkgname-$pkgver.tar.gz")
+sha256sums=('f73f1866f672db1941a2cb60b18532c185ef45b0950a538a6598e57791d32c02')
+
+prepare() {
+  cd $_hkgname-$pkgver
+  uusi -d semigroups $_hkgname.cabal
+}
+
+build() {
+  cd $_hkgname-$pkgver
+
+  runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+    --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+    --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+    --ghc-option=-optl-Wl\,-z\,relro\,-z\,now \
+    --ghc-option='-pie'
+
+  runhaskell Setup build
+  runhaskell Setup register --gen-script
+  runhaskell Setup unregister --gen-script
+  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+  cd $_hkgname-$pkgver
+  runhaskell Setup test
+}
+
+package() {
+  cd $_hkgname-$pkgver
+
+  install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+  install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+  runhaskell Setup copy --destdir="$pkgdir"
+  install -D -m644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
+  rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}