[arch-commits] Commit in haskell-modern-uri/repos (2 files)

[Felix Yan]

    Date: Saturday, February 13, 2021 @ 04:22:25
  Author: felixonmars
Revision: 857825

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-modern-uri/repos/community-staging-x86_64/
  haskell-modern-uri/repos/community-staging-x86_64/PKGBUILD
    (from rev 857824, haskell-modern-uri/trunk/PKGBUILD)

----------+
 PKGBUILD |   46 ++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)

Copied: haskell-modern-uri/repos/community-staging-x86_64/PKGBUILD (from rev 857824, haskell-modern-uri/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-02-13 04:22:25 UTC (rev 857825)
@@ -0,0 +1,46 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=modern-uri
+pkgname=haskell-modern-uri
+pkgver=0.3.3.1
+pkgrel=5
+pkgdesc="Modern library for working with URIs"
+url="https://github.com/mrkkrp/modern-uri"
+license=('BSD')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-quickcheck' 'haskell-contravariant' 'haskell-megaparsec'
+         'haskell-profunctors' 'haskell-reflection' 'haskell-tagged')
+makedepends=('ghc' 'haskell-hspec' 'haskell-hspec-megaparsec' 'haskell-hspec-discover')
+source=("https://hackage.haskell.org/packages/archive/$_hkgname/$pkgver/$_hkgname-$pkgver.tar.gz")
+sha512sums=('d81e2ef0ac5c44099bc87fdaec74b6c0789a8208d5a6656856645de11faab0b3b2392a30e2d1470116f52034723ab7b253910791bd722679aff56c6f9602aa2a')
+
+build() {
+  cd $_hkgname-$pkgver
+
+  runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+    --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+    --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+    --ghc-option=-optl-Wl\,-z\,relro\,-z\,now \
+    --ghc-option='-pie'
+
+  runhaskell Setup build $MAKEFLAGS
+  runhaskell Setup register --gen-script
+  runhaskell Setup unregister --gen-script
+  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+  cd $_hkgname-$pkgver
+  runhaskell Setup test
+}
+
+package() {
+  cd $_hkgname-$pkgver
+
+  install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+  install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+  runhaskell Setup copy --destdir="$pkgdir"
+  install -D -m644 LICENSE.md -t "$pkgdir"/usr/share/licenses/$pkgname/
+  rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE.md
+}