[arch-commits] Commit in arrayfire/repos (2 files)

[Konstantin Gizdov]

    Date: Monday, February 15, 2021 @ 23:04:58
  Author: kgizdov
Revision: 862185

archrelease: copy trunk to community-testing-x86_64

Added:
  arrayfire/repos/community-testing-x86_64/
  arrayfire/repos/community-testing-x86_64/PKGBUILD
    (from rev 862184, arrayfire/trunk/PKGBUILD)

----------+
 PKGBUILD |   57 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)

Copied: arrayfire/repos/community-testing-x86_64/PKGBUILD (from rev 862184, arrayfire/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2021-02-15 23:04:58 UTC (rev 862185)
@@ -0,0 +1,57 @@
+# Maintainer: Sven-Hendrik Haase <svenstaro at gmail.com>
+pkgname=arrayfire
+pkgver=3.8.0
+pkgrel=3
+pkgdesc="High performance software library for parallel computing with an easy-to-use API"
+arch=('x86_64')
+url='https://arrayfire.com'
+license=('BSD')
+depends=('cblas' 'fftw' 'lapacke' 'forge' 'freeimage' 'glfw' 'glew' 'intel-mkl')
+makedepends=('cmake' 'graphviz' 'doxygen' 'opencl-headers' 'python' 'ocl-icd' 'cuda' 'cudnn' 'git' 'ninja' 'boost')
+optdepends=('cuda: Required for using CUDA backend'
+            'nvidia-utils: Required for using CUDA backend'
+            'cudnn: Required for using CUDA backend'
+            'opencl-driver: Required for using OpenCL backend')
+options=('!buildflags')
+source=("http://github.com/${pkgname}/${pkgname}/releases/download/v${pkgver}/${pkgname}-full-${pkgver}.tar.bz2")
+sha512sums=('f36bee89a0f1a0a48ca2cae3a7b2527d63830e3070cb31174ff7f5c42f065aad6981d5142a8b7af7215a3c7dbf67ae13d1ea3543cd94eb70cff509c8cb95c739')
+
+build() {
+  cd "${srcdir}/arrayfire-full-${pkgver}"
+
+  cmake . \
+      -GNinja \
+      -Bbuild \
+      -DUSE_CPU_MKL=ON \
+      -DGOOGLETEST_VERSION=1.9.0 \
+      -DCMAKE_INSTALL_PREFIX=/usr \
+      -DCMAKE_INSTALL_LIBDIR=/usr/lib \
+      -DAF_WITH_IMAGEIO=ON \
+      -DAF_BUILD_CPU=ON \
+      -DAF_BUILD_OPENCL=ON \
+      -DAF_WITH_NONFREE=ON \
+      -DAF_BUILD_EXAMPLES=ON \
+      -DAF_BUILD_DOCS=ON \
+      -DCUDA_architecture_build_targets="5.2;5.3;6.0;6.1;6.2;7.0;7.2;7.5;8.0;8.6" \
+      -DCMAKE_BUILD_TYPE=Release \
+      -DCUDA_HOST_COMPILER=/usr/bin/gcc \
+      -DBoost_NO_BOOST_CMAKE=ON
+
+  ninja -C build
+}
+
+check() {
+  cd "${srcdir}/arrayfire-full-${pkgver}"
+
+  # Tests currently broken :(
+  # ninja -C build test
+}
+
+package() {
+  cd "${srcdir}/arrayfire-full-${pkgver}"
+
+  install -Dm644 LICENSE "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
+
+  DESTDIR="${pkgdir}/" ninja -C build install
+  rm -r "${pkgdir}"/usr/LICENSES
+}