[arch-commits] Commit in (gn-m87 gn-m87/repos gn-m87/trunk gn-m87/trunk/PKGBUILD)

Evangelos Foutras foutrelis at archlinux.org
Wed Feb 17 05:19:03 UTC 2021


    Date: Wednesday, February 17, 2021 @ 05:19:02
  Author: foutrelis
Revision: 408343

Add gn-m87 for chromium-based apps before M88

Added:
  gn-m87/
  gn-m87/repos/
  gn-m87/trunk/
  gn-m87/trunk/PKGBUILD

----------+
 PKGBUILD |   40 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 40 insertions(+)

Added: gn-m87/trunk/PKGBUILD
===================================================================
--- gn-m87/trunk/PKGBUILD	                        (rev 0)
+++ gn-m87/trunk/PKGBUILD	2021-02-17 05:19:02 UTC (rev 408343)
@@ -0,0 +1,40 @@
+# Maintainer: Evangelos Foutras <evangelos at foutrelis.com>
+
+pkgname=gn-m87
+pkgver=0.1831.e002e68a
+_commit=e002e68a48d1c82648eadde2f6aafa20d08c36f2
+pkgrel=1
+pkgdesc="Meta-build system that generates build files for Ninja"
+pkgdesc+=" (version shipped in Chromium 87; for apps using the set_sources_assignment_filter function; https://crbug.com/1018739)"
+arch=('x86_64')
+url="https://gn.googlesource.com/gn/"
+license=('BSD')
+depends=('gcc-libs')
+makedepends=('clang' 'ninja' 'python' 'git')
+source=(git+https://gn.googlesource.com/gn#commit=$_commit)
+sha256sums=('SKIP')
+
+pkgver() {
+  cd gn
+  echo 0.$(git rev-list --count initial-commit..).$(git rev-parse --short HEAD)
+}
+
+build() {
+  cd gn
+  ./build/gen.py
+  ninja -C out
+}
+
+check() {
+  cd gn
+  ./out/gn_unittests
+}
+
+package() {
+  cd gn
+  install -D out/gn "$pkgdir/usr/bin/gn-m87"
+  install -Dm644 -t "$pkgdir/usr/share/doc/$pkgname" docs/*
+  install -Dm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
+}
+
+# vim:set ts=2 sw=2 et:


More information about the arch-commits mailing list