[arch-commits] Commit in (waylock waylock/repos waylock/trunk waylock/trunk/PKGBUILD)
David Runge
dvzrv at archlinux.org
Wed Feb 17 19:34:41 UTC 2021
Date: Wednesday, February 17, 2021 @ 19:34:41
Author: dvzrv
Revision: 862637
Add waylock from the AUR.
Added:
waylock/
waylock/repos/
waylock/trunk/
waylock/trunk/PKGBUILD
----------+
PKGBUILD | 34 ++++++++++++++++++++++++++++++++++
1 file changed, 34 insertions(+)
Added: waylock/trunk/PKGBUILD
===================================================================
--- waylock/trunk/PKGBUILD (rev 0)
+++ waylock/trunk/PKGBUILD 2021-02-17 19:34:41 UTC (rev 862637)
@@ -0,0 +1,34 @@
+# Maintainer: David Runge <dvzrv at archlinux.org>
+
+pkgname=waylock
+pkgver=0.3.3
+pkgrel=2
+pkgdesc="A simple screenlocker for wayland compositors"
+arch=('x86_64')
+url="https://github.com/ifreund/waylock"
+license=('MIT')
+depends=('gcc-libs' 'glibc')
+makedepends=('git' 'pam' 'rust')
+_commit=2391ef614783b06ce4b88b14fb4a636fbb2a91a6 # refs/tags/v0.3.3^{}
+source=("git+https://github.com/ifreund/waylock#commit=${_commit}?signed")
+md5sums=('SKIP')
+validpgpkeys=('5FBDF84DD2278DB2B8AD8A5286DED400DDFD7A11') # Isaac Freund <ifreund at ifreund.xyz>
+
+build() {
+ cd "$pkgname"
+ cargo build --release --locked --all-features --target-dir=target
+}
+
+check() {
+ cd "$pkgname"
+ cargo test --release --locked --target-dir=target
+}
+
+package() {
+ depends+=('libpam.so')
+ cd "$pkgname"
+ install -vDm 755 target/release/${pkgname} -t "${pkgdir}/usr/bin"
+ install -vDm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
+ install -vDm 644 {README.md,waylock.toml} \
+ -t "${pkgdir}/usr/share/doc/${pkgname}"
+}
More information about the arch-commits
mailing list