[arch-commits] Commit in haskell-http-client/repos (2 files)

Felix Yan felixonmars at archlinux.org
Thu Feb 18 04:15:50 UTC 2021


    Date: Thursday, February 18, 2021 @ 04:15:50
  Author: felixonmars
Revision: 863494

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-http-client/repos/community-staging-x86_64/
  haskell-http-client/repos/community-staging-x86_64/PKGBUILD
    (from rev 863493, haskell-http-client/trunk/PKGBUILD)

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Copied: haskell-http-client/repos/community-staging-x86_64/PKGBUILD (from rev 863493, haskell-http-client/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-02-18 04:15:50 UTC (rev 863494)
@@ -0,0 +1,45 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=http-client
+pkgname=haskell-http-client
+pkgver=0.7.5
+pkgrel=12
+pkgdesc="An HTTP client engine"
+url="https://github.com/snoyberg/http-client"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-base64-bytestring' 'haskell-blaze-builder' 'haskell-case-insensitive'
+         'haskell-cookie' 'haskell-http-types' 'haskell-mime-types' 'haskell-network'
+         'haskell-network-uri' 'haskell-random' 'haskell-streaming-commons')
+makedepends=('ghc' 'haskell-async' 'haskell-hspec' 'haskell-monad-control' 'haskell-zlib')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('09980acde1c421293e3dbbcc7d7a59a213ffeb4c7136eff0e8276348779dcb5003496b9b8406c8b3c36a459910072c679a3177410ff116aa24ca7e0086583d4e')
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid -fnetwork-uri
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}


More information about the arch-commits mailing list