[arch-commits] Commit in haskell-haddock-library/repos (2 files)

[Felix Yan]

    Date: Saturday, February 20, 2021 @ 18:46:53
  Author: felixonmars
Revision: 866996

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-haddock-library/repos/community-staging-x86_64/
  haskell-haddock-library/repos/community-staging-x86_64/PKGBUILD
    (from rev 866995, haskell-haddock-library/trunk/PKGBUILD)

----------+
 PKGBUILD |   48 ++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

Copied: haskell-haddock-library/repos/community-staging-x86_64/PKGBUILD (from rev 866995, haskell-haddock-library/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-02-20 18:46:53 UTC (rev 866996)
@@ -0,0 +1,48 @@
+# Maintainer: Sergej Pupykin <arch+pub at sergej.pp.ru>
+
+_hkgname=haddock-library
+pkgname=haskell-haddock-library
+pkgver=1.9.0
+pkgrel=108
+pkgdesc="A documentation-generation tool for Haskell libraries"
+url="https://www.haskell.org/haddock/"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs')
+makedepends=('ghc' 'uusi' 'haskell-base-compat' 'haskell-hspec' 'haskell-hspec-discover'
+             'haskell-quickcheck' 'haskell-optparse-applicative' 'haskell-tree-diff')
+source=("https://hackage.haskell.org/packages/archive/haddock-library/${pkgver}/haddock-library-${pkgver}.tar.gz")
+sha512sums=('ec41df15a849a59fc41a443ce233dfa6293f0d201ed1847bd8a7732bc0e2138bab2305c127bd60f51919d8eeeb6808eec7a0add38edacd059956d852167477b5')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    uusi $_hkgname.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}