[arch-commits] Commit in haskell-yesod-form/repos (2 files)

[Felix Yan]

    Date: Wednesday, February 24, 2021 @ 09:43:34
  Author: felixonmars
Revision: 871148

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-yesod-form/repos/community-staging-x86_64/
  haskell-yesod-form/repos/community-staging-x86_64/PKGBUILD
    (from rev 871147, haskell-yesod-form/trunk/PKGBUILD)

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Copied: haskell-yesod-form/repos/community-staging-x86_64/PKGBUILD (from rev 871147, haskell-yesod-form/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-02-24 09:43:34 UTC (rev 871148)
@@ -0,0 +1,47 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=yesod-form
+pkgname=haskell-yesod-form
+pkgver=1.6.7
+pkgrel=390
+pkgdesc="Form handling support for Yesod Web Framework"
+url="http://www.yesodweb.com/"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-attoparsec' 'haskell-blaze-builder' 'haskell-blaze-html'
+         'haskell-blaze-markup' 'haskell-byteable' 'haskell-data-default' 'haskell-email-validate'
+         'haskell-network-uri' 'haskell-persistent' 'haskell-resourcet' 'haskell-shakespeare'
+         'haskell-wai' 'haskell-xss-sanitize' 'haskell-yesod-core' 'haskell-yesod-persistent')
+makedepends=('ghc')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('a23c2cb67ed0a87afde9e9e903aa789f8fd9c071893a1bebd0ff9dc3dec6e8e03dd08a4a7ef6ef2d438fbf62597ea0181a038bd7bb5631199c9be83d2a8aef0c')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    sed -i '/semigroups/d' $_hkgname.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -fnetwork-uri
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh   "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 "LICENSE" "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}