[arch-commits] Commit in glslang/repos (staging-x86_64 staging-x86_64/PKGBUILD)

[Sven-Hendrik Haase]

    Date: Wednesday, February 24, 2021 @ 15:12:17
  Author: svenstaro
Revision: 408738

archrelease: copy trunk to staging-x86_64

Added:
  glslang/repos/staging-x86_64/
  glslang/repos/staging-x86_64/PKGBUILD
    (from rev 408737, glslang/trunk/PKGBUILD)

----------+
 PKGBUILD |   51 +++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)

Copied: glslang/repos/staging-x86_64/PKGBUILD (from rev 408737, glslang/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2021-02-24 15:12:17 UTC (rev 408738)
@@ -0,0 +1,51 @@
+# Maintainer: Sven-Hendrik Haase <svenstaro at gmail.com>
+
+# Careful when upgrading this package! It usually breaks ABI without bumping soname.
+pkgname=glslang
+pkgver=11.2.0
+pkgrel=1
+pkgdesc='OpenGL and OpenGL ES shader front end and validator'
+arch=('x86_64')
+url='https://github.com/KhronosGroup/glslang'
+license=('BSD')
+depends=('gcc-libs' 'spirv-tools' 'python')
+makedepends=('cmake' 'ninja')
+options=('staticlibs')
+source=(${pkgname}-${pkgver}.tar.gz::https://github.com/KhronosGroup/glslang/archive/${pkgver}.tar.gz)
+sha256sums=('8ff2fcf9b054e4a4ef56fcd8a637322f827b2b176a592a618d63672ddb896e06')
+
+build() {
+  cd ${pkgname}-${pkgver}
+  mkdir -p build-{shared,static}
+  (cd build-shared
+    cmake .. \
+      -GNinja \
+      -DCMAKE_INSTALL_PREFIX=/usr \
+      -DCMAKE_BUILD_TYPE=Release \
+      -DBUILD_SHARED_LIBS=ON
+    ninja
+  )
+  (cd build-static
+    cmake .. \
+      -GNinja \
+      -DCMAKE_INSTALL_PREFIX=/usr \
+      -DCMAKE_BUILD_TYPE=Release \
+      -DBUILD_SHARED_LIBS=OFF
+    ninja
+  )
+}
+
+package() {
+  cd ${pkgname}-${pkgver}
+  DESTDIR="${pkgdir}" ninja -C build-shared install
+  DESTDIR="${pkgdir}" ninja -C build-static install
+
+  install -Dm644 LICENSE.txt "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
+
+  cd "${pkgdir}"/usr/lib
+  for lib in *.so; do
+    ln -sf "${lib}" "${lib}.0"
+  done
+}
+
+# vim: ts=2 sw=2 et: