[arch-commits] Commit in (smpeg smpeg/repos smpeg/trunk smpeg/trunk/PKGBUILD)

[Jan Steffens]

    Date: Friday, February 26, 2021 @ 23:08:18
  Author: heftig
Revision: 874487

extra2community: Moving smpeg from extra to community

Added:
  smpeg/
  smpeg/repos/
  smpeg/trunk/
  smpeg/trunk/PKGBUILD

----------+
 PKGBUILD |   33 +++++++++++++++++++++++++++++++++
 1 file changed, 33 insertions(+)

Added: smpeg/trunk/PKGBUILD
===================================================================
--- smpeg/trunk/PKGBUILD	                        (rev 0)
+++ smpeg/trunk/PKGBUILD	2021-02-26 23:08:18 UTC (rev 874487)
@@ -0,0 +1,33 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Contributor: Eric Belanger <eric at archlinux.org>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+
+pkgname=smpeg
+pkgver=0.4.5
+pkgrel=5
+pkgdesc="SDL MPEG Player Library"
+arch=(x86_64)
+url="https://icculus.org/smpeg/"
+license=(LGPL)
+depends=(sdl)
+makedepends=(mesa glu subversion)
+optdepends=('glu: to use glmovie')
+source=("$pkgname-$pkgver::svn://svn.icculus.org/smpeg/tags/release_${pkgver//./_}")
+sha256sums=('SKIP')
+
+prepare() {
+  cd $pkgname-$pkgver
+  ./autogen.sh
+}
+
+build() {
+  cd $pkgname-$pkgver
+  CFLAGS+=" -Wno-error=narrowing"
+  ./configure --prefix=/usr --mandir=/usr/share/man --disable-static
+  make
+}
+
+package() {
+  cd $pkgname-$pkgver
+  make DESTDIR="$pkgdir" install
+}