[arch-commits] Commit in pandoc-citeproc/repos (2 files)

[Felix Yan]

    Date: Friday, January 1, 2021 @ 06:43:09
  Author: felixonmars
Revision: 801930

archrelease: copy trunk to community-staging-x86_64

Added:
  pandoc-citeproc/repos/community-staging-x86_64/
  pandoc-citeproc/repos/community-staging-x86_64/PKGBUILD
    (from rev 801929, pandoc-citeproc/trunk/PKGBUILD)

----------+
 PKGBUILD |   58 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)

Copied: pandoc-citeproc/repos/community-staging-x86_64/PKGBUILD (from rev 801929, pandoc-citeproc/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-01-01 06:43:09 UTC (rev 801930)
@@ -0,0 +1,58 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+pkgname=pandoc-citeproc
+pkgver=0.17.0.2
+pkgrel=129
+pkgdesc="Supports using pandoc with citeproc"
+url="https://hackage.haskell.org/package/$pkgname"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-aeson-pretty' 'haskell-attoparsec'
+         'haskell-base-compat' 'haskell-data-default' 'haskell-hs-bibutils' 'haskell-libyaml'
+         'haskell-network' 'haskell-old-locale' 'pandoc' 'haskell-pandoc-types' 'haskell-rfc5051'
+         'haskell-safe' 'haskell-setenv' 'haskell-split' 'haskell-syb' 'haskell-tagsoup'
+         'haskell-temporary' 'haskell-text-icu' 'haskell-unordered-containers' 'haskell-vector'
+         'haskell-xml-conduit' 'haskell-yaml' 'haskell-hsyaml' 'haskell-hsyaml-aeson')
+conflicts=('haskell-pandoc-citeproc')
+replaces=('haskell-pandoc-citeproc')
+makedepends=('ghc' 'uusi')
+source=("https://hackage.haskell.org/packages/archive/$pkgname/${pkgver}/$pkgname-${pkgver}.tar.gz")
+sha512sums=('5ce079a542b096c06d6e4e205625a993422a972f04787495ac9013dd3131df62733f30e4c3004335e3738b02bb22a7ad50a31c1eb3f67d2b4ef51605c7fcbf16')
+
+prepare() {
+    cd "${srcdir}/$pkgname-${pkgver}"
+    uusi $pkgname.cabal
+    # TODO: find a better solution
+    sed -i "s|(\"HOME\",\".\")|(\"HOME\",\".\"),(\"LD_LIBRARY_PATH\",\"$PWD/dist/build\"),(\"pandoc_citeproc_datadir\",\"$PWD\")|" tests/test-pandoc-citeproc.hs
+}
+
+build() {
+    cd "${srcdir}/$pkgname-${pkgver}"
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/$pkgname" --datasubdir="$pkgname" --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -f-debug -f-test_citeproc -funicode_collation -f-embed_data_files -fbibutils -f-static
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $pkgname-$pkgver
+    # https://github.com/jgm/pandoc-citeproc/issues/342
+    runhaskell Setup test || echo "Tests failed"
+}
+
+package() {
+    cd "${srcdir}/$pkgname-${pkgver}"
+
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/$pkgname.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/$pkgname.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    install -D -m644 "LICENSE" "${pkgdir}/usr/share/licenses/$pkgname/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/$pkgname/LICENSE"
+}