[arch-commits] Commit in scribus/repos (2 files)

Felix Yan felixonmars at archlinux.org
Sat Jan 2 22:46:37 UTC 2021


    Date: Saturday, January 2, 2021 @ 22:46:37
  Author: felixonmars
Revision: 804856

archrelease: copy trunk to community-staging-x86_64

Added:
  scribus/repos/community-staging-x86_64/
  scribus/repos/community-staging-x86_64/PKGBUILD
    (from rev 804855, scribus/trunk/PKGBUILD)

----------+
 PKGBUILD |   53 +++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)

Copied: scribus/repos/community-staging-x86_64/PKGBUILD (from rev 804855, scribus/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-01-02 22:46:37 UTC (rev 804856)
@@ -0,0 +1,53 @@
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+# Contributor: Gaetan Bisson <bisson at archlinux.org>
+# Contributor: Daniel J Griffiths <ghost1227 at archlinux.us>
+# Contributor: Ronald van Haren <ronald.archlinux.org>
+# Contributor: tobias <tobias at archlinux.org>
+# Contributor: Ben <ben at benmazer.net>
+
+pkgname=scribus
+pkgver=1.5.6.1
+pkgrel=5
+pkgdesc="Desktop publishing software"
+arch=(x86_64)
+url="https://www.scribus.net/"
+license=(GPL)
+depends=(boost-libs cairo fontconfig freetype2 harfbuzz-icu hunspell lcms2
+         libcdr libcups libfreehand libjpeg libmspub libpagemaker libpng libqxp
+         librevenge libtiff libvisio libxml2 libzmf openscenegraph openssl
+         podofo poppler python3 qt5-base zlib) # graphicsmagick
+makedepends=(cmake boost mesa qt5-tools)
+optdepends=('tk: scripts based on tkinter'
+            'hyphen-lang: hyphenation patterns for desired languages')
+source=("https://downloads.sourceforge.net/${pkgname}/${pkgname}-${pkgver}.tar.xz"{,.asc})
+sha256sums=(d4257695539cfa40dead8abdaf04c51e34d4d74bcad5a2c934d08e6e9d43b7ab SKIP)
+validpgpkeys=(5086B8D68E70FDDF4C40045AEF7B95E7F60166DA  # Peter Linnell <plinnell at scribus.net>
+              757F5E9B13DD648887AD50092D47C099E782504E  # The Scribus Team (www.scribus.net) <the_scribus_team at scribus.net>
+              6558BE84D27273A438A151198BEA48118AEBEE64) # Craig Bradney <cbradney at zipworld.com.au>
+
+build() {
+    cmake -B build -S ${pkgname}-${pkgver} \
+        -DCMAKE_INSTALL_PREFIX=/usr \
+        -DCMAKE_BUILD_TYPE=None \
+        -DCMAKE_SKIP_RPATH=ON
+        # FS#59800
+        #-DWANT_GRAPHICSMAGICK=1
+    make -C build
+}
+
+package() {
+    make -C build DESTDIR="${pkgdir}" install
+
+    cd ${pkgname}-${pkgver}
+
+    install -Dm644 scribus.desktop -t "${pkgdir}"/usr/share/applications
+
+    for i in 16x16 32x32 128x128 256x256 512x512 1024x1024
+    do
+        install -Dm644 resources/iconsets/artwork/icon_${i}.png "${pkgdir}"/usr/share/icons/hicolor/${i}/apps/scribus.png
+    done
+
+    # Use system hyphen
+    rm -rf "${pkgdir}"/usr/share/scribus/dicts/hyph
+    ln -sf /usr/share/hyphen "${pkgdir}"/usr/share/scribus/dicts/hyph
+}



More information about the arch-commits mailing list