[arch-commits] Commit in python-scipy/repos (2 files)

[Antonio Rojas]

    Date: Sunday, January 3, 2021 @ 22:30:08
  Author: arojas
Revision: 806023

archrelease: copy trunk to community-testing-x86_64

Added:
  python-scipy/repos/community-testing-x86_64/
  python-scipy/repos/community-testing-x86_64/PKGBUILD
    (from rev 806022, python-scipy/trunk/PKGBUILD)

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Copied: python-scipy/repos/community-testing-x86_64/PKGBUILD (from rev 806022, python-scipy/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2021-01-03 22:30:08 UTC (rev 806023)
@@ -0,0 +1,45 @@
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Thomas Dziedzic < gostrc at gmail >
+# Contributor: Angel 'angvp' Velasquez <angvp[at]archlinux.com.ve>
+# Contributor: Ray Rashif <schiv at archlinux.org>
+# Contributor: Douglas Soares de Andrade <dsa at aur.archlinux.org>
+# Contributor: Bodor Dávid Gábor <david.gabor.bodor at gmail.com>
+# Contributor: Andrzej Giniewicz <gginiu at gmail.com>
+
+_name=scipy
+pkgname=python-scipy
+pkgver=1.6.0
+pkgrel=1
+pkgdesc="SciPy is open-source software for mathematics, science, and engineering."
+arch=('x86_64')
+url="https://www.scipy.org/"
+license=(BSD)
+depends=(python-numpy)
+provides=(scipy)
+makedepends=(gcc-fortran python-setuptools pybind11)
+checkdepends=(python-pytest)
+optdepends=('python-pillow: for image saving module')
+source=("https://pypi.python.org/packages/source/${_name:0:1}/$_name/$_name-$pkgver.tar.gz")
+sha256sums=('cb6dc9f82dfd95f6b9032a8d7ea70efeeb15d5b5fd6ed4e8537bb3c673580566')
+
+build() {
+  cd scipy-${pkgver}
+  python setup.py config_fc build
+}
+
+check() {
+  cd scipy-${pkgver}
+  python setup.py config_fc install \
+    --prefix=/usr --root="$srcdir"/test --optimize=1
+  export PYTHONPATH="$srcdir"/test/usr/lib/python3.9/site-packages
+  cd ..
+  python -c "from scipy import test; test('full')"
+}
+
+package() {
+  cd scipy-$pkgver
+  python3 setup.py config_fc install \
+    --prefix=/usr --root="$pkgdir" --optimize=1
+
+  install -Dm644 LICENSE.txt -t "$pkgdir"/usr/share/licenses/$pkgname
+}