[arch-commits] Commit in haskell-ghc-lib-parser-ex/repos (2 files)

[Felix Yan]

    Date: Tuesday, January 5, 2021 @ 12:40:46
  Author: felixonmars
Revision: 808997

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-ghc-lib-parser-ex/repos/community-staging-x86_64/
  haskell-ghc-lib-parser-ex/repos/community-staging-x86_64/PKGBUILD
    (from rev 808996, haskell-ghc-lib-parser-ex/trunk/PKGBUILD)

----------+
 PKGBUILD |   42 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)

Copied: haskell-ghc-lib-parser-ex/repos/community-staging-x86_64/PKGBUILD (from rev 808996, haskell-ghc-lib-parser-ex/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-01-05 12:40:46 UTC (rev 808997)
@@ -0,0 +1,42 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=ghc-lib-parser-ex
+pkgname=haskell-ghc-lib-parser-ex
+pkgver=8.10.0.17
+pkgrel=11
+pkgdesc="Algorithms on GHC parse trees"
+url="https://github.com/shayne-fletcher/ghc-lib-parser-ex"
+license=('BSD')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-uniplate' 'haskell-ghc')
+makedepends=('ghc' 'haskell-extra' 'haskell-tasty' 'haskell-tasty-hunit' 'haskell-uniplate')
+source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
+sha512sums=('193cac08c898aed5c8e8f4f60ff140b2c5adf7fce84832e843b1a1bc2e2bf184972ad91f1baa47d744c7a4bdf3fa87cb6513b5ca3d02f79765d7c36574c8be9e')
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}