[arch-commits] Commit in plasma-desktop/repos/extra-x86_64 (PKGBUILD PKGBUILD)

[Antonio Rojas]

    Date: Tuesday, January 5, 2021 @ 15:52:07
  Author: arojas
Revision: 405314

archrelease: copy trunk to extra-x86_64

Added:
  plasma-desktop/repos/extra-x86_64/PKGBUILD
    (from rev 405313, plasma-desktop/trunk/PKGBUILD)
Deleted:
  plasma-desktop/repos/extra-x86_64/PKGBUILD

----------+
 PKGBUILD |  112 ++++++++++++++++++++++++++++---------------------------------
 1 file changed, 53 insertions(+), 59 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2021-01-05 15:51:58 UTC (rev 405313)
+++ PKGBUILD	2021-01-05 15:52:07 UTC (rev 405314)
@@ -1,59 +0,0 @@
-# Maintainer: Felix Yan <felixonmars at archlinux.org>
-# Maintainer: Antonio Rojas <arojas at archlinux.org>
-# Contributor: Andrea Scarpino <andrea at archlinux.org>
-
-pkgbase=plasma-desktop
-pkgname=(plasma-desktop knetattach)
-pkgver=5.20.4
-pkgrel=2
-pkgdesc='KDE Plasma Desktop'
-arch=(x86_64)
-url='https://www.kde.org/workspaces/plasmadesktop/'
-license=(LGPL)
-source=("https://download.kde.org/stable/plasma/$pkgver/$pkgname-$pkgver.tar.xz"{,.sig}
-         kdebug-429314.patch::"https://invent.kde.org/plasma/plasma-desktop/commit/036fd9d1.patch")
-depends=(polkit-kde-agent libxkbfile kmenuedit systemsettings ksysguard baloo libibus accountsservice)
-makedepends=(extra-cmake-modules kdoctools xf86-input-evdev xf86-input-synaptics xf86-input-libinput xorg-server-devel
-             scim kdesignerplugin kaccounts-integration intltool)
-groups=(plasma)
-sha256sums=('3864e80bb9b8da596188162b14cd9bb77e7a8abedfb0fa41c8c72d47139d1355'
-            'SKIP'
-            '3a9edde572da99cbf235b235da8ea79da1ef9540c28130045798cec8592d60e9')
-validpgpkeys=('2D1D5B0588357787DE9EE225EC94D18F7F05997E'  # Jonathan Riddell <jr at jriddell.org>
-              '0AAC775BB6437A8D9AF7A3ACFE0784117FBCE11D'  # Bhushan Shah <bshah at kde.org>
-              'D07BD8662C56CB291B316EB2F5675605C74E02CF'  # David Edmundson <davidedmundson at kde.org>
-              '1FA881591C26B276D7A5518EEAAF29B42A678C20') # Marco Martin <notmart at gmail.com>
-
-prepare() {
-  patch -d $pkgbase-$pkgver -p1 -i ../kdebug-429314.patch # Fix race condition in users KCM
-}
-
-build() {
-  cmake -B build -S $pkgname-$pkgver \
-    -DCMAKE_INSTALL_LIBEXECDIR=lib \
-    -DBUILD_TESTING=OFF
-  cmake --build build
-}
-
-package_plasma-desktop() {
-  depends+=(knetattach)
-  optdepends=('plasma-nm: Network manager applet'
-              'powerdevil: power management, suspend and hibernate support'
-              'kscreen: screen management'
-              'ibus: kimpanel IBUS support'
-              'scim: kimpanel SCIM support'
-              'kaccounts-integration: OpenDesktop integration plugin')
-  replaces=(user-manager)
-
-  DESTDIR="$pkgdir" cmake --install build
-
-# Split knetattach
-  rm "$pkgdir"/usr/{bin/knetattach,share/applications/org.kde.knetattach.desktop}
-}
-
-package_knetattach() {
-  pkgdesc='Wizard which makes it easier to integrate network resources with the Plasma Desktop'
-  depends=(kdelibs4support)
-
-  DESTDIR="$pkgdir" cmake --install build/knetattach
-}

Copied: plasma-desktop/repos/extra-x86_64/PKGBUILD (from rev 405313, plasma-desktop/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2021-01-05 15:52:07 UTC (rev 405314)
@@ -0,0 +1,53 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Andrea Scarpino <andrea at archlinux.org>
+
+pkgbase=plasma-desktop
+pkgname=(plasma-desktop knetattach)
+pkgver=5.20.5
+pkgrel=1
+pkgdesc='KDE Plasma Desktop'
+arch=(x86_64)
+url='https://kde.org/plasma-desktop/'
+license=(LGPL)
+source=("https://download.kde.org/stable/plasma/$pkgver/$pkgname-$pkgver.tar.xz"{,.sig})
+depends=(polkit-kde-agent libxkbfile kmenuedit systemsettings ksysguard baloo libibus accountsservice)
+makedepends=(extra-cmake-modules kdoctools xf86-input-evdev xf86-input-synaptics xf86-input-libinput xorg-server-devel
+             scim kdesignerplugin kaccounts-integration intltool)
+groups=(plasma)
+sha256sums=('bd656e93f44fd528bcd2e0e4c79cbc1adb837369f9a27291bcc5dcd9df2787b9'
+            'SKIP')
+validpgpkeys=('2D1D5B0588357787DE9EE225EC94D18F7F05997E'  # Jonathan Riddell <jr at jriddell.org>
+              '0AAC775BB6437A8D9AF7A3ACFE0784117FBCE11D'  # Bhushan Shah <bshah at kde.org>
+              'D07BD8662C56CB291B316EB2F5675605C74E02CF'  # David Edmundson <davidedmundson at kde.org>
+              '1FA881591C26B276D7A5518EEAAF29B42A678C20') # Marco Martin <notmart at gmail.com>
+
+build() {
+  cmake -B build -S $pkgname-$pkgver \
+    -DCMAKE_INSTALL_LIBEXECDIR=lib \
+    -DBUILD_TESTING=OFF
+  cmake --build build
+}
+
+package_plasma-desktop() {
+  depends+=(knetattach)
+  optdepends=('plasma-nm: Network manager applet'
+              'powerdevil: power management, suspend and hibernate support'
+              'kscreen: screen management'
+              'ibus: kimpanel IBUS support'
+              'scim: kimpanel SCIM support'
+              'kaccounts-integration: OpenDesktop integration plugin')
+  replaces=(user-manager)
+
+  DESTDIR="$pkgdir" cmake --install build
+
+# Split knetattach
+  rm "$pkgdir"/usr/{bin/knetattach,share/applications/org.kde.knetattach.desktop}
+}
+
+package_knetattach() {
+  pkgdesc='Wizard which makes it easier to integrate network resources with the Plasma Desktop'
+  depends=(kdelibs4support)
+
+  DESTDIR="$pkgdir" cmake --install build/knetattach
+}