[arch-commits] Commit in wpewebkit/trunk (PKGBUILD)
Jan Steffens
heftig at archlinux.org
Tue Jan 5 15:52:42 UTC 2021
Date: Tuesday, January 5, 2021 @ 15:52:41
Author: heftig
Revision: 405319
2.30.4-2
Added:
wpewebkit/trunk/PKGBUILD
----------+
PKGBUILD | 60 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 60 insertions(+)
Added: PKGBUILD
===================================================================
--- PKGBUILD (rev 0)
+++ PKGBUILD 2021-01-05 15:52:41 UTC (rev 405319)
@@ -0,0 +1,60 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+
+pkgname=wpewebkit
+pkgver=2.30.4
+pkgrel=2
+pkgdesc="Web content engine for embedded devices"
+url="https://wpewebkit.org"
+arch=(x86_64)
+license=(custom)
+depends=(cairo fontconfig freetype2 glib2 harfbuzz harfbuzz-icu icu libjpeg
+ libepoxy libgcrypt libsoup libxml2 zlib libpng sqlite libwebp libwpe
+ atk at-spi2-atk openjpeg2 woff2 libtasn1 libxslt libsystemd bubblewrap
+ libseccomp xdg-dbus-proxy gstreamer gst-plugins-base-libs libxkbcommon
+ wayland wpebackend-fdo)
+makedepends=(cmake ninja gtk-doc python ruby systemd gst-plugins-bad gperf
+ wayland-protocols)
+optdepends=('geoclue: Geolocation support'
+ 'gst-plugins-good: media decoding'
+ 'gst-plugins-bad: media decoding'
+ 'gst-libav: nonfree media decoding')
+source=($url/releases/$pkgname-$pkgver.tar.xz{,.asc})
+sha256sums=('1e521d85cf8cf344b9fd08eabad7a1d18a330fb7862a77eaf78d7d7b10d5f6ef'
+ 'SKIP')
+validpgpkeys=('D7FCF61CF9A2DEAB31D81BD3F3D322D0EC4582C3' # Carlos Garcia Campos <cgarcia at igalia.com>
+ '5AA3BC334FD7E3369E7C77B291C559DBE4C9123B') # Adrián Pérez de Castro <aperez at igalia.com>
+
+prepare() {
+ cd $pkgname-$pkgver
+}
+
+build() {
+ cmake -S $pkgname-$pkgver -B build -G Ninja \
+ -DPORT=WPE \
+ -DCMAKE_BUILD_TYPE=Release \
+ -DCMAKE_INSTALL_PREFIX=/usr \
+ -DCMAKE_INSTALL_LIBDIR=lib \
+ -DCMAKE_INSTALL_LIBEXECDIR=lib \
+ -DCMAKE_SKIP_RPATH=ON \
+ -DENABLE_GTKDOC=ON \
+ -DENABLE_MINIBROWSER=ON
+ cmake --build build
+}
+
+package() {
+ depends+=(libwpe-1.0.so libWPEBackend-fdo-1.0.so)
+ provides+=(libWPEWebKit-1.0.so)
+
+ DESTDIR="$pkgdir" cmake --install build
+
+ cd $pkgname-$pkgver
+ find Source -name 'COPYING*' -or -name 'LICENSE*' -print0 | sort -z |
+ while IFS= read -d $'\0' -r _f; do
+ echo "### $_f ###"
+ cat "$_f"
+ echo
+ done |
+ install -Dm644 /dev/stdin "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
+
+# vim:set sw=2 et:
More information about the arch-commits
mailing list