[arch-commits] Commit in webkit2gtk/repos/extra-x86_64 (PKGBUILD PKGBUILD)

[Jan Steffens]

    Date: Tuesday, January 5, 2021 @ 16:38:54
  Author: heftig
Revision: 405331

archrelease: copy trunk to extra-x86_64

Added:
  webkit2gtk/repos/extra-x86_64/PKGBUILD
    (from rev 405330, webkit2gtk/trunk/PKGBUILD)
Deleted:
  webkit2gtk/repos/extra-x86_64/PKGBUILD

----------+
 PKGBUILD |  127 +++++++++++++++++++++++++++++--------------------------------
 1 file changed, 62 insertions(+), 65 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2021-01-05 16:38:41 UTC (rev 405330)
+++ PKGBUILD	2021-01-05 16:38:54 UTC (rev 405331)
@@ -1,65 +0,0 @@
-# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
-# Contributor: Eric Bélanger <eric at archlinux.org>
-
-pkgname=webkit2gtk
-pkgver=2.30.4
-pkgrel=2
-pkgdesc="GTK+ Web content engine library"
-arch=(x86_64)
-url="https://webkitgtk.org/"
-license=(custom)
-depends=(libxt libxslt enchant gst-plugins-base-libs libsecret libwebp openjpeg2
-         harfbuzz-icu gtk3 libnotify hyphen woff2 libwpe wpebackend-fdo
-         bubblewrap xdg-dbus-proxy)
-makedepends=(gperf gobject-introspection ruby gtk-doc cmake python geoclue
-             gst-plugins-bad ninja)
-optdepends=('geoclue: Geolocation support'
-            'gst-plugins-good: media decoding'
-            'gst-plugins-bad: media decoding'
-            'gst-libav: nonfree media decoding')
-source=(https://webkitgtk.org/releases/webkitgtk-${pkgver}.tar.xz{,.asc})
-sha256sums=('d595a37c5001ff787266b155e303a5f2e5b48a6d466f2714c2f30c11392f7b24'
-            'SKIP')
-validpgpkeys=('D7FCF61CF9A2DEAB31D81BD3F3D322D0EC4582C3'
-              '5AA3BC334FD7E3369E7C77B291C559DBE4C9123B')
-
-prepare() {
-  cd webkitgtk-$pkgver
-}
-
-build() {
-  CFLAGS+=" $CPPFLAGS"
-  CXXFLAGS+=" $CPPFLAGS"
-  cmake -S webkitgtk-$pkgver -B build -G Ninja \
-    -DPORT=GTK \
-    -DCMAKE_BUILD_TYPE=Release \
-    -DCMAKE_INSTALL_PREFIX=/usr \
-    -DCMAKE_SKIP_RPATH=ON \
-    -DENABLE_GTKDOC=ON \
-    -DENABLE_MINIBROWSER=ON \
-    -DLIBEXEC_INSTALL_DIR=/usr/lib \
-    -DLIB_INSTALL_DIR=/usr/lib
-  cmake --build build
-}
-
-check() {
-  : cmake --build build --target tests
-}
-
-package() {
-  depends+=(libwpe-1.0.so libWPEBackend-fdo-1.0.so)
-  provides+=(libjavascriptcoregtk-4.0.so libwebkit2gtk-4.0.so)
-
-  DESTDIR="$pkgdir" cmake --install build
-
-  cd webkitgtk-$pkgver
-  find Source -name 'COPYING*' -or -name 'LICENSE*' -print0 | sort -z |
-    while IFS= read -d $'\0' -r _f; do
-      echo "### $_f ###"
-      cat "$_f"
-      echo
-    done |
-    install -Dm644 /dev/stdin "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
-}
-
-# vim:set sw=2 et:

Copied: webkit2gtk/repos/extra-x86_64/PKGBUILD (from rev 405330, webkit2gtk/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2021-01-05 16:38:54 UTC (rev 405331)
@@ -0,0 +1,62 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Eric Bélanger <eric at archlinux.org>
+
+pkgname=webkit2gtk
+pkgver=2.30.4
+pkgrel=3
+pkgdesc="Web content engine for GTK"
+url="https://webkitgtk.org"
+arch=(x86_64)
+license=(custom)
+depends=(cairo fontconfig freetype2 libgcrypt glib2 gtk3 harfbuzz harfbuzz-icu
+         icu libjpeg libsoup libxml2 zlib libpng sqlite atk libwebp at-spi2-core
+         libegl libgl libgles libwpe wpebackend-fdo libxslt libsecret libtasn1
+         enchant libx11 libxext libice libxt wayland libnotify hyphen openjpeg2
+         woff2 libsystemd bubblewrap libseccomp xdg-dbus-proxy gstreamer
+         gst-plugins-base-libs)
+makedepends=(cmake ninja gtk-doc python ruby gobject-introspection
+             wayland-protocols systemd gst-plugins-bad gperf)
+optdepends=('geoclue: Geolocation support'
+            'gst-plugins-good: media decoding'
+            'gst-plugins-bad: media decoding'
+            'gst-libav: nonfree media decoding')
+source=($url/releases/webkitgtk-$pkgver.tar.xz{,.asc})
+sha256sums=('d595a37c5001ff787266b155e303a5f2e5b48a6d466f2714c2f30c11392f7b24'
+            'SKIP')
+validpgpkeys=('D7FCF61CF9A2DEAB31D81BD3F3D322D0EC4582C3'  # Carlos Garcia Campos <cgarcia at igalia.com>
+              '5AA3BC334FD7E3369E7C77B291C559DBE4C9123B') # Adrián Pérez de Castro <aperez at igalia.com>
+
+prepare() {
+  cd webkitgtk-$pkgver
+}
+
+build() {
+  cmake -S webkitgtk-$pkgver -B build -G Ninja \
+    -DPORT=GTK \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_INSTALL_LIBDIR=lib \
+    -DCMAKE_INSTALL_LIBEXECDIR=lib \
+    -DCMAKE_SKIP_RPATH=ON \
+    -DENABLE_GTKDOC=ON \
+    -DENABLE_MINIBROWSER=ON
+  cmake --build build
+}
+
+package() {
+  depends+=(libwpe-1.0.so libWPEBackend-fdo-1.0.so)
+  provides+=(libjavascriptcoregtk-4.0.so libwebkit2gtk-4.0.so)
+
+  DESTDIR="$pkgdir" cmake --install build
+
+  cd webkitgtk-$pkgver
+  find Source -name 'COPYING*' -or -name 'LICENSE*' -print0 | sort -z |
+    while IFS= read -d $'\0' -r _f; do
+      echo "### $_f ###"
+      cat "$_f"
+      echo
+    done |
+    install -Dm644 /dev/stdin "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
+
+# vim:set sw=2 et: