[arch-commits] Commit in (sip4 sip4/trunk sip4/trunk/PKGBUILD)
Antonio Rojas
arojas at archlinux.org
Tue Jan 5 17:51:45 UTC 2021
Date: Tuesday, January 5, 2021 @ 17:51:43
Author: arojas
Revision: 405336
Rename sip to sip4
Added:
sip4/
sip4/trunk/
sip4/trunk/PKGBUILD
----------+
PKGBUILD | 53 +++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 53 insertions(+)
Added: sip4/trunk/PKGBUILD
===================================================================
--- sip4/trunk/PKGBUILD (rev 0)
+++ sip4/trunk/PKGBUILD 2021-01-05 17:51:43 UTC (rev 405336)
@@ -0,0 +1,53 @@
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Andrea Scarpino <andrea at archlinux.org>
+# Contributor: Douglas Soares de Andrade <douglas at archlinux.org>
+# Contributor: riai <riai at bigfoot.com>, Ben <ben at benmazer.net>
+
+pkgbase=sip4
+pkgname=(sip4 python-sip4)
+pkgver=4.19.24
+pkgrel=1
+arch=(x86_64)
+url='https://www.riverbankcomputing.com/software/sip/intro'
+license=('custom:"sip"')
+makedepends=(python)
+source=("https://www.riverbankcomputing.com/static/Downloads/sip/$pkgver/sip-$pkgver.tar.gz")
+sha256sums=('edcd3790bb01938191eef0f6117de0bf56d1136626c0ddb678f3a558d62e41e5')
+
+prepare() {
+ mkdir -p build
+}
+
+build() {
+ cd build
+ python ../sip-$pkgver/configure.py CFLAGS="$CFLAGS" LFLAGS="$LDFLAGS"
+ make
+}
+
+package_sip4() {
+ pkgdesc="A tool that makes it easy to create Python bindings for C and C++ libraries"
+ depends=(glibc)
+ replaces=('sip<5')
+
+ cd build
+ make DESTDIR="$pkgdir" install -C sipgen
+# move sip.h to /usr/include
+ mv "$pkgdir"/usr/include/{python*/sip.h,}
+ rm -r "$pkgdir"/usr/include/python*
+
+ install -Dm644 ../sip-$pkgver/LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+package_python-sip4() {
+ pkgdesc="Python SIP4 bindings for C and C++ libraries"
+ depends=(python)
+ provides=(python-sip)
+ replaces=(python-sip)
+
+ cd build
+ make DESTDIR="$pkgdir" install
+ rm -r "$pkgdir"/usr/{bin,include} # conflicts with sip
+
+ install -Dm644 ../sip-$pkgver/LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
More information about the arch-commits
mailing list