[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Wednesday, January 6, 2021 @ 18:23:14
  Author: felixonmars
Revision: 811312

addpkg: python-aiogram 2.11.2-3

Added:
  python-aiogram/
  python-aiogram/repos/
  python-aiogram/trunk/
  python-aiogram/trunk/PKGBUILD

----------+
 PKGBUILD |   48 ++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

Added: python-aiogram/trunk/PKGBUILD
===================================================================
--- python-aiogram/trunk/PKGBUILD	                        (rev 0)
+++ python-aiogram/trunk/PKGBUILD	2021-01-06 18:23:14 UTC (rev 811312)
@@ -0,0 +1,48 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Evgeniy Filimonov <evgfilim1 at gmail.com>
+
+pkgname=python-aiogram
+pkgver=2.11.2
+pkgrel=3
+pkgdesc="A pretty simple and fully asynchronous library for Telegram Bot API written with asyncio and aiohttp"
+arch=('any')
+url="https://github.com/aiogram/aiogram"
+license=('MIT')
+depends=('python-aiohttp' 'python-babel')
+makedepends=('python-setuptools')
+checkdepends=('python-aiohttp-socks' 'python-aioredis' 'python-aresponses' 'python-pytest' 'pifpaf' 'redis')
+optdepends=('python-uvloop: fast, drop-in replacement of the built-in asyncio event loop'
+            'python-ujson: ultra fast JSON encoder and decoder written in pure C'
+            'python-rapidjson: extremely fast C++ JSON parser and serialization library'
+            'python-emoji: emojize and demojize support'
+            'python-aioredis: Redis storage support'
+            'python-aiohttp-socks: SOCKS4(a) and SOCKS5 proxy support'
+#            'python-rethinkdb: RethinkDB storage support'  # No such package yet
+)
+source=("$url/archive/v$pkgver/$pkgname-$pkgver.tar.gz")
+sha256sums=('8a56570704a278534c9158c832a307b82215df1608c076d7a4842a7fc77e75d6')
+
+prepare() {
+  cd aiogram-$pkgver
+  sed -e '/import certifi/d' \
+      -e 's|certifi.where()|"/etc/ssl/certs/ca-certificates.crt"|' \
+      -i aiogram/bot/base.py
+}
+
+build() {
+  cd aiogram-$pkgver
+  python setup.py build
+}
+
+check() {
+  cd aiogram-$pkgver
+  pifpaf run redis -- bash -c 'python -m pytest --redis $PIFPAF_REDIS_URL'
+}
+
+package() {
+  cd aiogram-$pkgver
+  python setup.py install --root="$pkgdir" --optimize=1 --skip-build
+
+  install -Dm644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
+  install -Dm644 README.md -t "$pkgdir"/usr/share/doc/$pkgname/
+}