[arch-commits] Commit in hoel (3 files)

[Maxime Gauduin]

    Date: Thursday, January 7, 2021 @ 10:22:41
  Author: alucryd
Revision: 811546

archrelease: copy trunk to community-staging-x86_64

Added:
  hoel/repos/
  hoel/repos/community-staging-x86_64/
  hoel/repos/community-staging-x86_64/PKGBUILD
    (from rev 811545, hoel/trunk/PKGBUILD)

----------+
 PKGBUILD |   55 +++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)

Copied: hoel/repos/community-staging-x86_64/PKGBUILD (from rev 811545, hoel/trunk/PKGBUILD)
===================================================================
--- repos/community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ repos/community-staging-x86_64/PKGBUILD	2021-01-07 10:22:41 UTC (rev 811546)
@@ -0,0 +1,55 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+
+pkgname=hoel
+pkgver=1.4.17
+pkgrel=1
+pkgdesc='C Database abstraction library with json based language'
+arch=(x86_64)
+url=https://github.com/babelouest/hoel
+license=(LGPL2.1)
+depends=(
+  glibc
+  jansson
+  liborcania.so
+  libyder.so
+)
+makedepends=(
+  cmake
+  doxygen
+  git
+  graphviz
+  mariadb-libs
+  ninja
+  postgresql-libs
+  sqlite
+)
+optdepends=(
+  'postgresql-libs: PostgreSQL support'
+  'mariadb-libs: MariaDB support'
+  'sqlite: SQLite support'
+)
+_tag=57b6849e793966180cf43849cfe3d1dbfb964572
+source=(git+https://github.com/babelouest/hoel.git#tag=${_tag})
+validpgpkeys=(8405B02FCC28EF9744C8F253FE82139440BD22B9) # Nicolas Mora <nicolas at babelouest.org>
+b2sums=(SKIP)
+
+pkgver() {
+  cd hoel
+  git describe --tags | sed 's/^v//'
+}
+
+build() {
+  cmake -S hoel -B build -G Ninja \
+    -DCMAKE_BUILD_TYPE=None \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DBUILD_HOEL_DOCUMENTATION=ON
+  ninja -C build doc
+}
+
+package() {
+  DESTDIR="${pkgdir}" ninja -C build install
+  install -dm 755 "${pkgdir}"/usr/share/doc/hoel
+  cp -dr --no-preserve=ownership hoel/doc/html "${pkgdir}"/usr/share/doc/hoel/
+}
+
+# vim: ts=2 sw=2 et: